SAS delete row when a column is non numeric - sas

Question

I have this dataset student in SAS and I planned to delete the records(rows) where grade is non numeric. I tried the following code and it didnt worked. I tried 'if grade=. then delete;' as well and it still didnt work. I do not want to replace the values and I just want to delete the row. Any ideas on this?
data student;
infile datalines firstobs=2 dsd truncover;
input student$ class$ grade;
datalines;
student, class, grade
Jansen, Brave, A
Yassin, Brave, 70
Benison, Brave, 67
Yan Jin, Brave, E
James, Hero, 90
Michelle, Hero, 89
Hiroku, Hero, C
Misoku, Hero, 93
;
run;
data student_cleaned;
set work.student;
if not (anyalpha(grade)) then delete;
run;

Answer 1

In the first step you read in grade as numeric. This means SAS will already have removed any characters from that data set. Read it in as character and then you can do the second step. Add a $ after grade to read it in as a character value.
Literally a one character change ;)
data student;
infile datalines firstobs=2 dsd truncover;
input student$ class$ grade $;
datalines;
student, class, grade
Jansen, Brave, A
Yassin, Brave, 70
Benison, Brave, 67
Yan Jin, Brave, E
James, Hero, 90
Michelle, Hero, 89
Hiroku, Hero, C
Misoku, Hero, 93
;
run;
data student_cleaned;
set work.student;
if anyalpha(grade) then delete;
run;

Answer 2

You already read GRADE as a numeric variable. The single letter codes like A or E will be mapped to the corresponding special missing values like .A or .E. Any other text will be mapped to regular missing.
You can use the MISSING() function to test for any of those.
if missing(grade) then delete;