Prolog List Manipulation Assistance - list

Question

I have a prolog homework problem that I've been working on that I'm rather stuck on. The basic problem is that I have three lists, each of which has members containing a phrase and a value. I am supposed to randomly select a member of the list, print the phrase, and repeat until I've printed phrases from at least two of the lists, and the total value of the phrases printed is at least 9.
What I've done so far: I've gone through several dozen iterations of the program, and searched the SWI documentation as well as Lean Prolog Now and stack overflow. In the process I've learned that using assert() to add an item to a list will cause corruption on a subsequent run, all variables are local, that appending a single item to an empty list does not result in a list but does result in fun error messages the next recursion, and that you can't vary a variable's value.
My program successfully does the following: randomly chooses one of 3 lists. Randomly grabs an item from that list. Places the phrase and value from the selected item into different variables, and prints them.
Its main issue is that my list manipulation does not appear to be working. The line "append(Usedlist, Z, Usedlist3)," always fails in the second iteration of the code without throwing an error. Additionally, I believe that the member(Z, Usedlist) is not working as the rare occasions where I randomly get a repeat in the second iteration it does not function properly. However, I suspect that the fault is in the append not adding to the list properly.
Relevant code (condensed to 1 list for sanity reasons)
main :-
A is 0,
B is 0,
C is 0,
Num is 0,
Usedlist = ["Garbage data1", "More garbage data"],
prologwhile(Num, A, B, C, Usedlist).
prologwhile(Num, A, B, C, Usedlist) :- Num < 9 ,
F = [["time of day", 1], ["Season", 5], ["Yesterdays weather", 2], ["Month of last big storm", 2], ["Randomly generated riddle", 9], ["A captcha", 1], ['Current day', 6], ["Tomorrows date", 5]],
random_member(Rand, F),
nth0(1, Rand, Add),
writeln(Rand),
nth0(0, Rand, Z),
writeln(Usedlist),
( member(Z, Usedlist) ->
writeln("Test5"),
prologwhile(Num, A, B, C, Usedlist)
; writeln(Rand),
writeln(Add),
writeln("Test6"),
append(Usedlist, Z, Usedlist3),
writeln(Z),
C3 is 1,
Num3 is Num + Add,
writeln(Num3),
prologwhile(Num3, A, B, C3, Usedlist3)
)
Sample output
[Tomorrows date,5]
[Garbage data1,More garbage data]
[Tomorrows date,5]
5
Test6
Tomorrows date
5
[time of day,1]
[Garbage data1,More garbage data|Tomorrows date]
[time of day,1]
1
Test6
false.

Answer 1

Let us tackle it in stages:
1. Eliminate side-effects and simplify the program
I start with the following straight-forward changes of your program:
I eliminate all goals that perform I/O, since these only get in the way of the reasoning we would like to perform about the program.
Instead of X is C where C is a constant, and the variable is only used once in the remainder of the code, I simply use the constant C directly.
Thus, we obtain:
main :-
prologwhile(0, 0, 0, 0, ["Garbage data1", "More garbage data"]).
prologwhile(Num, A, B, C, Usedlist) :-
Num < 9 ,
F = [["time of day", 1], ["Season", 5], ["Yesterdays weather", 2], ["Month of last big storm", 2], ["Randomly generated riddle", 9], ["A captcha", 1], ['Current day', 6], ["Tomorrows date", 5]],
random_member(Rand, F),
nth0(1, Rand, Add),
nth0(0, Rand, Z),
( member(Z, Usedlist) ->
prologwhile(Num, A, B, C, Usedlist)
; append(Usedlist, Z, Usedlist3),
Num3 is Num + Add,
prologwhile(Num3, A, B, 1, Usedlist3)
).
Now, for readability, I make the following additional changes:
I factor out the phrases into their own predicate
I use pairs instead of lists to represent Phrase-Value pairs
I use pattern matching and a bit more telling variable names.
In total, we now have:
main :-
prologwhile(0, 0, 0, 0, ["Garbage data1", "More garbage data"]).
prologwhile(Num, A, B, C, Usedlist) :-
Num < 9 ,
phrases(Ps),
random_member(Phrase-Value, Ps),
( member(Phrase, Usedlist) ->
prologwhile(Num, A, B, C, Usedlist)
; append(Usedlist, Phrase, Usedlist3),
Num3 is Num + Value,
prologwhile(Num3, A, B, 1, Usedlist3)
).
phrases(["time of day"-1,
"Season"-5,
"Yesterdays weather"-2,
"Month of last big storm"-2,
"Randomly generated riddle"-9,
"A captcha"-1,
'Current day'-6,
"Tomorrows date"-5]).
Henceforth, I assume phrases/1 as defined in the above snippet, and do not carry its definition along.
2. Find the cause of the failure
Now the actual reasoning about the program starts, because we have:
?- main.
false.
To help you find the mistake, I add the following definition to the program:
$(Goal) :-
portray_clause(Goal),
Goal.
We can use this predicate as follows in prologwhile/5:
prologwhile(Num, A, B, C, Usedlist) :-
Num < 9 ,
phrases(Ps),
random_member(Phrase-Value, Ps),
( member(Phrase, Usedlist) ->
prologwhile(Num, A, B, C, Usedlist)
; $(append(Usedlist, Phrase, Usedlist3)),
Num3 is Num + Value,
prologwhile(Num3, A, B, 1, Usedlist3)
).
We now get:
?- main.
append(["Garbage data1", "More garbage data"], "A captcha", _).
append(["Garbage data1", "More garbage data"|"A captcha"], 'Current day', _).
false.
So here's the problem:
?- append(["Garbage data1", "More garbage data"|"A captcha"], 'Current day', _).
false
This goal fails, and hence the whole program fails.
You obviously intended the following:
append(Usedlist, [Phrase], Usedlist3)
i.e., you want to append a the contents of two lists, not that of a list and something else. Note that it is often a good idea to prepend elements in front of a list instead of appending them to obtain good performance, so we can write this as:
Usedlist3 = [Phrase|Usedlist]
So, the whole predicate becomes:
prologwhile(Num, A, B, C, Usedlist) :-
Num < 9 ,
phrases(Ps),
random_member(Phrase-Value, Ps),
( member(Phrase, Usedlist) ->
prologwhile(Num, A, B, C, Usedlist)
; Usedlist3 = [Phrase|Usedlist],
Num3 is Num + Value,
prologwhile(Num3, A, B, 1, Usedlist3)
).
Or shorter:
prologwhile(Num, A, B, C, Usedlist) :-
Num < 9 ,
phrases(Ps),
random_member(Phrase-Value, Ps),
( member(Phrase, Usedlist) ->
prologwhile(Num, A, B, C, Usedlist)
; Num3 is Num + Value,
prologwhile(Num3, A, B, 1, [Phrase|Usedlist])
).
However, we still have:
?- main.
false.
To see why this still fails, think about the cases in which the predicate ought to hold. After a bit of reflection, the following is a case in which it should hold:
prologwhile(Num, _, _, _, [_,_|_]) :- Num >= 9.
Thus, we add the case to our program, obtaining:
prologwhile(Num, _, _, _, [_,_|_]) :- Num >= 9.
prologwhile(Num, A, B, C, Usedlist) :-
Num < 9 ,
phrases(Ps),
random_member(Phrase-Value, Ps),
( member(Phrase, Usedlist) ->
prologwhile(Num, A, B, C, Usedlist)
; Num3 is Num + Value,
prologwhile(Num3, A, B, 1, [Phrase|Usedlist])
).
Note how I am using pattern matching on the accumulated list to detect the case that elements from at least 2 different pairs are used.
Now, we at last have:
?- main.
true .
That's pretty cool, but not that useful.
3. Report the actual solution on the toplevel
Now, it is time to ask a few deeper questions about the program. For example, what are all these arguments really doing here? Let us simply forget about A, B and C, obtaining:
main :-
prologwhile(0, ["Garbage data1", "More garbage data"]).
prologwhile(Num, [_,_|_]) :- Num >= 9.
prologwhile(Num, Usedlist) :-
Num < 9 ,
phrases(Ps),
random_member(Phrase-Value, Ps),
( member(Phrase, Usedlist) ->
prologwhile(Num, Usedlist)
; Num3 is Num + Value,
prologwhile(Num3, [Phrase|Usedlist])
).
It works just as well:
?- main.
true .
On the other hand, an important thing seems to be missing, namely the phrases we have actually used! Let us get them by introducing an argument that represents them. In such situations, a useful naming convention is a pair Ls0 and Ls, with Ls0 denoting the initial list, and Ls the final one that we want the toplevel to report.
We can also simply forget about the "garbage" elements.
Thus the whole program becomes:
solution(List) :-
prologwhile(0, [], List).
prologwhile(Num, Ls, Ls) :- Num >= 9, Ls = [_,_|_].
prologwhile(Num, Ls0, Ls) :-
Num < 9 ,
phrases(Ps),
random_member(Phrase-Value, Ps),
( member(Phrase, Ls0) ->
prologwhile(Num, Ls0, Ls)
; Num3 is Num + Value,
prologwhile(Num3, [Phrase|Ls0], Ls)
).
phrases(["time of day"-1,
"Season"-5,
"Yesterdays weather"-2,
"Month of last big storm"-2,
"Randomly generated riddle"-9,
"A captcha"-1,
'Current day'-6,
"Tomorrows date"-5]).
Sample query:
?- solution(Ls).
Ls = ["Randomly generated riddle", "Season"] ;
false.
You can also easily extend this to report the total value, either while building the list or in a simple additional step. I leave this as an exercise. Note also that prologwhileisnotaseasytoread as for example using_underscores_would_be.