SAS - Remove duplicated words in a string - sas

Question

string = "spanner, span, spaniel, span";
From this string I would like to remove all the duplicates keeping one occurrence of the word and then output the revised string using SAS.
The revised string should look like this:
var string = "spanner, span, spaniel";

Answer 1

data a;
string = "spanner,span,spaniel,span,abc,span,bcc";
length word $100;
i = 2;
do while(scan(string, i, ',') ^= '');
word = scan(string, i, ',');
do j = 1 to i - 1;
if word = scan(string, j, ',') then do;
start = findw(string, word, ',', findw(string, word, ',', 't') + 1, 't');
string = cats(substr(string, 1, start - 2), substr(string, start + length(word)));
leave;
end;
end;
i = i + 1;
end;
keep string;
run;

Answer 2

First create a data set with one column containing the words. With cats() the space is eliminated.
data temp(keep=text);
string = "spanner, span, spaniel, span";
do i=1 to count(cats(string),",")+1;
text = scan(string,i);
output;
end;
run;
Eliminate duplicates with nodup (nodupkey also works).
proc sort data=temp nodup;
by text;
run;
Create a macro variable new_string with the unique words.
proc sql noprint;
SELECT text
INTO :new_string separated by ","
FROM temp
;
quit;
Better solution for new specifications:
data temp(keep=i text);
string = tranwrd("I hate the product. I hate it because it smells bad. I hate wasting money.","."," ."); do i=1 to count(string," ")+1;
text = scan(string,i," ");
if text ne "" then do;
output;
end;
end;
run;
proc sort data=temp;
by text i;
run;
data temp2;
set temp;
by text i;
if first.text OR text eq ".";
run;
proc sort data=temp2;
by i;
run;
proc sql noprint;
SELECT text
INTO :new_string separated by ","
FROM temp
;
quit;

Answer 3

Build the list of unique words into a new variable.
data test;
input string $80.;
length newstring $80;
do i=1 to countw(string,',');
if not findw(newstring,scan(string,i,','),',','t') then
newstring=catx(', ',newstring,scan(string,i,','))
;
end;
cards;
spanner, span, spaniel, span
;

Answer 4

Thanks Robert. Just wanted to let you know I found a flaw in your Code. The inner loop modifies the string by removing the duplicate word, but the outer loop checks the next position of the original string no matter what. Example: "A,B,C,B,B" becomes "A,B,C,B" because the inner loop removes the fourth B and then the outer loop doesn't find the last "B" because it moved to the position of the fourth "B".
My solution:
data a;
string = "spanner,span,spaniel,span,abc,span,bcc";
length word $100;
i = 2;
do while(scan(string, i, ',') ^= '');
hit = 0;
word = scan(string, i, ',');
do j = 1 to i - 1;
if word = scan(string, j, ',') then do;
start = findw(string, word, ',', findw(string, word, ',', 't') + 1, 't');
string = cats(substr(string, 1, start - 2), substr(string, start + length(word)));
hit = 1;
leave;
end;
end;
if hit = 0 then i = i + 1;
end;
keep string;
run;