How do I use Oracle regular expression to separate text by '\R\'? - regex

Question

I'd like to execute for~loop using the \R\ delimiter.
DECLARE
v_idx NUMBER := 1;
v_text VARCHAR2(1000);
v_pattern VARCHAR2(32);
BEGIN
v_text := 'GR105^INF^191097-1^CT^test string r01\R\GR109^INF^191097-2^CR^test string r02 (1234)';
v_pattern := '\\R\\';
FOR repeat IN (SELECT trim(REGEXP_SUBSTR(v_text, v_pattern, 1, LEVEL)) item
FROM dual
CONNECT BY LEVEL <= REGEXP_COUNT(v_text, v_pattern))
LOOP
dbms_output.PUT_LINE('--------------- ' || v_idx || ' ---------------');
dbms_output.PUT_LINE('v_a = ' || trim(REGEXP_SUBSTR(repeat.item, '[^^]+', 1, 1)));
dbms_output.PUT_LINE('v_b = ' || trim(REGEXP_SUBSTR(repeat.item, '[^^]+', 1, 2)));
dbms_output.PUT_LINE('v_c = ' || trim(REGEXP_SUBSTR(repeat.item, '[^^]+', 1, 3)));
dbms_output.PUT_LINE('v_d = ' || trim(REGEXP_SUBSTR(repeat.item, '[^^]+', 1, 4)));
dbms_output.PUT_LINE('v_e = ' || trim(REGEXP_SUBSTR(repeat.item, '[^^]+', 1, 5)));
v_idx := v_idx + 1;
END LOOP;
END;
It works fine with '~' separator and '[^~]+' pattern.
But I don't know how to use '\R\'

Answer 1

You are only matching the delimiter \R\ and not the preceding sub-string. To match the preceding sub-string you can match (.*?)(\\R\\|$) and extract the contents of the first capturing group:
DECLARE
v_idx NUMBER := 1;
v_text VARCHAR2(1000);
v_pattern VARCHAR2(32);
BEGIN
v_text := 'GR105^INF^191097-1^CT^test string r01\R\GR109^INF^191097-2^CR^test string r02 (1234)';
v_pattern := '(.*?)(\\R\\|$)';
FOR repeat IN (SELECT trim(REGEXP_SUBSTR(v_text, v_pattern, 1, LEVEL, NULL, 1)) item
FROM dual
CONNECT BY LEVEL < REGEXP_COUNT(v_text, v_pattern))
LOOP
dbms_output.PUT_LINE('--------------- ' || v_idx || ' ---------------');
dbms_output.PUT_LINE('v_a = ' || trim(REGEXP_SUBSTR(repeat.item, '[^^]+', 1, 1)));
dbms_output.PUT_LINE('v_b = ' || trim(REGEXP_SUBSTR(repeat.item, '[^^]+', 1, 2)));
dbms_output.PUT_LINE('v_c = ' || trim(REGEXP_SUBSTR(repeat.item, '[^^]+', 1, 3)));
dbms_output.PUT_LINE('v_d = ' || trim(REGEXP_SUBSTR(repeat.item, '[^^]+', 1, 4)));
dbms_output.PUT_LINE('v_e = ' || trim(REGEXP_SUBSTR(repeat.item, '[^^]+', 1, 5)));
v_idx := v_idx + 1;
END LOOP;
END;
/
Note: LEVEL <= REGEXP_COUNT(v_text, v_pattern) needs to change to LEVEL < REGEXP_COUNT(v_text, v_pattern) as there will be a final zero-width match from the pattern (on .*?$) that needs to be ignored.
Which outputs:
--------------- 1 ---------------
v_a = GR105
v_b = INF
v_c = 191097-1
v_d = CT
v_e = test string r01
--------------- 2 ---------------
v_a = GR109
v_b = INF
v_c = 191097-2
v_d = CR
v_e = test string r02 (1234)
fiddle