I want to esttab specific variable in one row
Use data in Stata
eststo clear
sysuse auto
eststo: quietly regress price weight mpg
eststo: quietly regress price weight foreign
esttab
--------------------------------------------
(1) (2)
price price
--------------------------------------------
weight 1.747** 3.321***
(2.72) (8.39)
mpg -49.51
(-0.57)
foreign 3637.0***
(5.44)
_cons 1946.1 -4942.8***
(0.54) (-3.67)
--------------------------------------------
N 74 74
--------------------------------------------
t statistics in parentheses
* p<0.05, ** p<0.01, *** p<0.001
What I need is mpg and foreign result in the same line.
In my data the variable have similar names.
like var_1 var_2 var3
--------------------------------------------
(1) (2)
price price
--------------------------------------------
weight 1.747** 3.321***
(2.72) (8.39)
mpg/foregin -49.51 3637.0***
(-0.57) (5.44)
_cons 1946.1 -4942.8***
(0.54) (-3.67)
--------------------------------------------
N 74 74
--------------------------------------------
t statistics in parentheses
* p<0.05, ** p<0.01, *** p<0.001
That would typically indicate a covariate that is a ratio of mpg and foreign, which is not what you have. I would avoid doing that since it makes it hard for people to tell what is different about your specifications when they are used to a certain table grammar and could even be perceived as dishonest. It also does not tell you which variable is in which specification.
But it can be done like this:
esttab, rename(mpg "mpg or foreign" foreign "mpg or foreign"). esttab, rename(mpg "mpg or foreign" foreign "mpg or foreign") varwidth(15)
-----------------------------------------------
(1) (2)
price price
-----------------------------------------------
weight 1.747** 3.321***
(2.72) (8.39)
mpg or foreign -49.51 3637.0***
(-0.57) (5.44)
_cons 1946.1 -4942.8***
(0.54) (-3.67)
-----------------------------------------------
N 74 74
-----------------------------------------------
t statistics in parentheses
* p<0.05, ** p<0.01, *** p<0.001
Related
I have run two regressions on similar but different data sets and regressors the results of which I want to report next to each other for comparability but keep them in one table using estout/esttab. The finished product should look something like this.
Table
-----------------------------------------
Dep. Var.: a
-----------------------------------------
Regression 1 |Regression 2
-----------------------------------------
x_1 coeff.|x_2 coeff.
y_1 coeff.|y_2 coeff.
z_1 coeff.|z_2 coeff.
l_1 coeff.|
m_1 coeff.|
-----------------------------------------
Obs value|Obs value
-----------------------------------------
Hypothesis |
x_1=1,p-value |x_2=1,p-value
-----------------------------------------
I am able to create individual tables like this just fine but I have honestly no idea where to start here and documentation hasn't been very helpful either. I hope someone here can point me in the right direction.
I think the eststo/esttab syntax will help. Here's code which I think produces what you're after:
ssc install estout, replace
sysuse auto, clear
eststo m1: regress price mpg
test mpg=1
estadd scalar pvalue = r(p)
eststo m2: regress price mpg trunk [enter image description here][1]
test trunk=1
estadd scalar pvalue = r(p)
esttab m1 m2, b(3) se(3) stats(pvalue r2 N, fmt(3 3 0) label("P-value" "R-squared" "Observations")) mtitle("Regression 1" "Regression 2") nocons
It creates this table:
--------------------------------------------
(1) (2)
Regression 1 Regression 2
--------------------------------------------
mpg -238.894*** -220.165**
(53.077) (65.593)
trunk 43.559
(88.719)
--------------------------------------------
P-value 0.000 0.633
R-squared 0.220 0.222
Observations 74 74
--------------------------------------------
Standard errors in parentheses
* p<0.05, ** p<0.01, *** p<0.001
The esttab guide is really great.
I want to describe characteristics of cars by origin, and retrieve the result as latex table:
sysuse auto
estpost tabstat price trunk, by(foreign) statistics(mean sd) columns(statistics) listwise nototal
esttab using test.txt, main(mean) aux(sd)
Already after the estpost I can feel that the labels are going missing: it correctly displays the value labels "Domestic" and "Foreign", but simply lists the variables as "price" and "trunk" instead of "Price" and "Trunk space".
I have seen this problem on the internet, but no solution is satisfactory. Some suggest fsum, but that doesn't really allow latex, and also no cross-tabulation (means of x by category y).
How can I fix this?
I automatized the accepted's answer as follows:
local varlabels
foreach var in price trunk {
local varlabels `"`varlabels' `var' "`:variable label `var''""'
}
The varlabels option allows you to add custom labels. After the estpost command the names of the estimates look like this:
. mat l e(mean)
e(mean)[1,4]
Domestic: Domestic: Foreign: Foreign:
price trunk price trunk
mean 6072.4231 14.75 6384.6818 11.409091
You can replace these names with variable labels with the addition of some code:
sysuse auto
estpost tabstat price trunk, by(foreign) statistics(mean sd) columns(statistics) listwise nototal
foreach name in `:colfullnames e(mean)' {
foreach var in price trunk {
if strpos("`name'", "`var'") > 0 {
local varlabels `"`varlabels' `name' "`:variable label `var''""'
}
}
}
di `"`varlabels'"'
esttab, main(mean) aux(sd) varlabels(`varlabels')
Result:
. di `"`varlabels'"'
Domestic:price "Price" Domestic:trunk "Trunk space (cu. ft.)" Foreign:price "Price" Foreign:trunk "Trunk space (cu. ft.)"
. esttab, main(mean) aux(sd) varlabels(`varlabels')
----------------------------
(1)
----------------------------
Domestic
Price 6072.4
(3097.1)
Trunk.. ft.) 14.75
(4.306)
----------------------------
Foreign
Price 6384.7
(2621.9)
Trunk.. ft.) 11.41
(3.217)
----------------------------
N 74
----------------------------
mean coefficients; sd in parentheses
* p<0.05, ** p<0.01, *** p<0.001
When adding option unstack to esttab, Domestic and Foreign are used as column names and the names of the coefficients are only price and trunk, so you could do something like this:
esttab, main(mean) aux(sd) unstack varlabels(price "`:variable label price'" trunk "`:variable label trunk'")
I am trying to create a summary statistics table by subgroup, using estout in Stata. My efforts have been drawing off of the official estout online documentation.
I want the counts of each subgroup to appear in the final table. I know that noobs in the last line removes the observation count. However, if I include noobs only the total observation count is included and not the count for the individual subgroups.
For example:
. sysuse auto
(1978 Automobile Data)
. estpost tabstat price mpg rep78, by(foreign) statistics(mean sd) ///
columns(statistics) listwise
Summary statistics: mean sd
for variables: price mpg rep78
by categories of: foreign
foreign | e(mean) e(sd)
-------------+----------------------
Domestic |
price | 6179.25 3188.969
mpg | 19.54167 4.753312
rep78 | 3.020833 .837666
-------------+----------------------
Foreign |
price | 6070.143 2220.984
mpg | 25.28571 6.309856
rep78 | 4.285714 .7171372
-------------+----------------------
Total |
price | 6146.043 2912.44
mpg | 21.28986 5.866408
rep78 | 3.405797 .9899323
. esttab, main(mean) aux(sd) nostar unstack noobs nonote nomtitle nonumber
---------------------------------------------------
Domestic Foreign Total
---------------------------------------------------
price 6179.2 6070.1 6146.0
(3189.0) (2221.0) (2912.4)
mpg 19.54 25.29 21.29
(4.753) (6.310) (5.866)
rep78 3.021 4.286 3.406
(0.838) (0.717) (0.990)
---------------------------------------------------
The following does what you are looking for:
clear
sysuse auto
by foreign: eststo: estpost summarize price mpg rep78, listwise
eststo Total: estpost summarize price mpg rep78, listwise
esttab, main(mean) aux(sd) nostar nonote label nonumber nodepvar
-----------------------------------------------------------
Domestic Foreign Total
-----------------------------------------------------------
Price 6179.2 6070.1 6146.0
(3189.0) (2221.0) (2912.4)
Mileage (mpg) 19.54 25.29 21.29
(4.753) (6.310) (5.866)
Repair Record 1978 3.021 4.286 3.406
(0.838) (0.717) (0.990)
-----------------------------------------------------------
Observations 48 21 69
-----------------------------------------------------------
I would like to use esttab (ssc install estout) to generate summary statistics by group with columns for the mean difference and significance. It is easy enough to generate these as two separate tables with estpost, summarize, and ttest, and combine manually, but I would like to automate the whole process.
The following code generates the two components of the desired table.
sysuse auto, clear
* summary statistics by group
eststo clear
by foreign: eststo: quietly estpost summarize ///
price mpg weight headroom trunk
esttab, cells("mean sd") label nodepvar
* difference in means
eststo: estpost ttest price mpg weight headroom trunk, ///
by(foreign) unequal
esttab ., wide label
And I can print the two tables and cut-an-paste into one table.
* can generate similar tables and append horizontally
esttab, cells("mean sd") label
esttab, wide label
* manual, cut-and-paste solution
-------------------------------------------------------------------------------------------------------
(1) (2) (3)
mean sd mean sd
-------------------------------------------------------------------------------------------------------
Price 6072.423 3097.104 6384.682 2621.915 -312.3 (-0.44)
Mileage (mpg) 19.82692 4.743297 24.77273 6.611187 -4.946** (-3.18)
Weight (lbs.) 3317.115 695.3637 2315.909 433.0035 1001.2*** (7.50)
Headroom (in.) 3.153846 .9157578 2.613636 .4862837 0.540** (3.30)
Trunk space (.. ft.) 14.75 4.306288 11.40909 3.216906 3.341*** (3.67)
-------------------------------------------------------------------------------------------------------
Observations 52 22 74
-------------------------------------------------------------------------------------------------------
t statistics in parentheses
* p<0.05, ** p<0.01, *** p<0.001
It seems that I should be able to get the desired table with one esttab call and without cutting-and-pasting, but I can't figure it out. Is there a way to generate the desired table without manually cutting-and-pasting?
I would prefer to output a LaTeX table, but anything that eliminates the cutting-and-pasting is a big step, even passing through a delimited text file.
If you still want to use esttab, you can play around using cells and pattern. The table in the original post can be replicated with the following code:
sysuse auto, clear
eststo domestic: quietly estpost summarize ///
price mpg weight headroom trunk if foreign == 0
eststo foreign: quietly estpost summarize ///
price mpg weight headroom trunk if foreign == 1
eststo diff: quietly estpost ttest ///
price mpg weight headroom trunk, by(foreign) unequal
esttab domestic foreign diff, ///
cells("mean(pattern(1 1 0) fmt(2)) sd(pattern(1 1 0)) b(star pattern(0 0 1) fmt(2)) t(pattern(0 0 1) par fmt(2))") ///
label
which yields
-----------------------------------------------------------------------------------------------------
(1) (2) (3)
mean sd mean sd b t
-----------------------------------------------------------------------------------------------------
Price 6072.42 3097.10 6384.68 2621.92 -312.26 (-0.44)
Mileage (mpg) 19.83 4.74 24.77 6.61 -4.95** (-3.18)
Weight (lbs.) 3317.12 695.36 2315.91 433.00 1001.21*** (7.50)
Headroom (in.) 3.15 0.92 2.61 0.49 0.54** (3.30)
Trunk space (.. ft.) 14.75 4.31 11.41 3.22 3.34*** (3.67)
-----------------------------------------------------------------------------------------------------
Observations 52 22 74
-----------------------------------------------------------------------------------------------------
I don't think there's a way to do this with esttab (estout package from ssc), but I have a solution with listtab (also ssc) and postfile. The table here is a little different than the one I propose above, but the approach is general enough that you can modify it to fit your needs.
This solution also use LaTeX's booktabs package.
/* data and variables */
sysuse auto, clear
local vars price mpg weight headroom trunk
/* means */
tempname postMeans
tempfile means
postfile `postMeans' ///
str100 varname domesticMeans foreignMeans pMeans using "`means'", replace
foreach v of local vars {
local name: variable label `v'
ttest `v', by(foreign)
post `postMeans' ("`name'") (r(mu_1)) (r(mu_2)) (r(p))
}
postclose `postMeans'
/* medians */
tempname postMedians
tempfile medians
postfile `postMedians' ///
domesticMedians foreignMedians pMedians using `medians', replace
foreach v of local vars {
summarize `v' if !foreign, detail
local med1 = r(p50)
summarize `v' if foreign, detail
local med2 = r(p50)
ranksum `v', by(foreign)
local pval = 2 * (1 - normal(abs(r(z))))
post `postMedians' (`med1') (`med2') (`pval')
}
postclose `postMedians'
/* combine */
use `means'
merge 1:1 _n using `medians', nogenerate
format *Means *Medians %9.3gc
list
/* make latex table */
/* requires LaTeX package `booktabs` */
listtab * using "Table.tex", ///
rstyle(tabular) replace ///
head("\begin{tabular}{lcccccc}" ///
"\toprule" ///
"& \multicolumn{3}{c}{Means} & \multicolumn{3}{c}{Medians} \\" ///
"\cmidrule(lr){2-4} \cmidrule(lr){5-7}" ///
"& Domestic & Foreign & \emph{p} & Domestic & Foreign & \emph{p}\\" ///
"\midrule") ///
foot("\bottomrule" "\end{tabular}")
This yields the following.
The answer chosen is nice but a bit redudant. You can achieve the same result with only estpost ttest.
sysuse auto, clear
estpost ttest price mpg weight headroom trunk, by(foreign)
esttab, cells("mu_1 mu_2 b(star)"
The output looks like this:
mu_1 mu_2 b
c_score 43.33858 42.034 1.30458***
nc_a4_17 4.007524 3.924623 .0829008*
Is there any way to save and reload data in between an eststo command and an esttab?
What I would love is something like the following:
eststo: quietly reg a b
estsave using foo.est, replace
***
*Some other File
estload using foo.est
esttab foo.tex
Any other alternatives that let me play with the way I output regressions by trial and error (without having to re-run them and having to be at an interactive prompt) would be enormously helpful.
Why do you need to put it to disk?
The (prefix) command eststo stores the results in memory until you close the file, and unless specified names each estimate consecutively (eststo1, eststo2 etc.). You can re-program and re-run only part of the do file.
Alternatively, you could create all estimates in a do and call it from a secondary do:
/* .do for make tables */
do makeEstimates.do
esttab ...
Elsewhere you program makeEstimates.do:
/* .do to make estimates */
quietly regress a b
estout ab
You can run once, then comment out the do makeEstimates.do line to just work on estout if you do not change them.
You can store estimates on disk with the estimates save command:
sysuse auto, clear
quietly regress price mpg
estimates save foo1
quietly regress price trunk
estimates save foo2
quietly regress price weight
estimates save foo3
The above code snippet creates 3 files in your current working directory containing the estimates:
foo1.ster
foo2.ster
foo3.ster
You can then reload these and use them with esttab non-interactively and in any way you like with the estimates use command:
estimates use foo2
esttab .
----------------------------
(1)
price
----------------------------
trunk 216.7**
(2.81)
_cons 3183.5**
(2.87)
----------------------------
N 74
----------------------------
t statistics in parentheses
* p<0.05, ** p<0.01, *** p<0.001
estimates use foo1
esttab .
----------------------------
(1)
price
----------------------------
mpg -238.9***
(-4.50)
_cons 11253.1***
(9.61)
----------------------------
N 74
----------------------------
t statistics in parentheses
* p<0.05, ** p<0.01, *** p<0.001
estimates use foo3
esttab .
----------------------------
(1)
price
----------------------------
weight 2.044***
(5.42)
_cons -6.707
(-0.01)
----------------------------
N 74
----------------------------
t statistics in parentheses
* p<0.05, ** p<0.01, *** p<0.001