SAS: Convert multiple columns to numeric - sas

Question

I have imported a dataset into SAS using proc import from an excel spreadsheet. All of the numeric columns are now characters, so is there a way of (cleanly) converting them all to numeric.
It doesn't work if I do the following:
data rf;
set rf;
rfage = input(rfage, 8.);
run;
So, I need to create a new column, then drop the old one:
data rf;
set rf;
rfage1 = input(rfage, 8.);
drop rfage;
rename rfage = rfage;
run;
Is there a way that I can convert a large number of columns to numeric (either this way, or a better way), using arrays and a do over loop if possible?
data rf;
set rf;
array to_numeric rfage -- rfprevparticipant;
do over to_numeric;
* Some function to convert to numeric here;
end;
run;
Alternatively, is there a way to change proc import to import numeric columns correctly in the first place?

Answer 1

See if you can use this as a template
data have;
array r $ rf1 - rf10;
do _N_ = 1 to 10;
do over r;
r = put(rand('integer', 1, 10), 8.);
end;
output;
end;
run;
data want;
set have;
array rnum num_rf1 - num_rf10;
array r $ rf1 - rf10;
do over rnum;
rnum = input(r, 8.);
end;
run;

Answer 2

The best solution would be to fix it at the source.
Something causes PROC IMPORT to guess that these columns are characters, and there could be a lot of valid reasons:
Header with more than 1 row
NULL, NA, N/A values
Alternatively, if you want to convert all characters variables to numeric in a table you could use the following macro that generates the drop and rename so that you keep the original names.
data have;
set sashelp.cars;
run;
%macro chartonum(in, out);
/* get char var names and position */
proc contents noprint data=have out=varname(keep=name type npos where=(type=2));
run;
/* yields char vars in the order they appear in the data set*/
proc sort;
by npos;
run;
data _null_;
do i=1 to nobs;
set varname nobs=nobs end=end;
call symput('mac'||left(put(i,4.)),name); /*creates macro variables for name of vars*/
call symput('num'||left(put(i,4.)),'num'||left(put(i,4.))); /*creates new macro numeric vars*/
if end then call symput('end',put(nobs,8.)); /*determines number of variables, 1 per obs*/
end;
run;
data &out.(drop= %do i=1 %to &end;&&mac&i %end;
rename=(
%do i=1 %to &end;
&&num&i=&&mac&i
%end;
));
%do i=1 %to &end;
set &in.;
/*create numeric macro vars, which resolve to num1-num5*/
&&num&i=input(&&mac&i,5.);
%end;
run;
%mend;
%chartonum(have, want);

Answer 3

You can still use Kermit's macro. Instead of using the where= option in the proc contents, define the have dataset with only the variables you want to change.
I'll walk through an example. The example below is going to convert some numeric vars into char vars because it's easier to illustrate. First, we'll need some test data, so I'm creating a copy of sashelp.baseball in the work library.
* create test data;
data baseball;
set sashelp.baseball;
run;
The primary work up front is to create a template of the data you want to change. In the example, I am using a variable list in the keep statement to identify the numeric vars I want to convert. Variables lists are really powerful for specifying many variables without typing each one. The style I used is just one of a few different ways to write variable lists.
data templt;
stop;
set baseball;
* use variable lists to easily address large groups of vars;
keep YrMajor-numeric-Salary; * keeps only numeric vars even if char vars are between them;
run;
The variable list in the keep statement captures all the numeric variables between YrMajor and Salary ignoring any character variables between them. The number of variables kept is 11. Notice that the template has no data because it's not needed for this exercise. We only need the metadata about the variables.
Once the template is defined, use it in the macro to create the code needed to change the data. Here's my version of the macro.
%macro change(in, out, tmplt);
* capture var names from template into a macro var;
proc sql noprint;
select
name into :varnames separated by ' '
from sashelp.vcolumn
where
libname = 'WORK'
and memname = "%upcase(&tmplt)"
order by npos
;
quit;
%let varcnt = %sysfunc(countw(&varnames));
%put NOTE: &=varcnt &=varnames;
data &out (drop=%do i = 1 %to &varcnt; oldvar&i %end;);
set &in
(rename=(
%do i = 1 %to &varcnt;
%scan(&varnames, &i)=oldvar&i
%end;
));
length %do i = 1 %to &varcnt; %scan(&varnames, &i) %end; $12;
%do i = 1 %to &varcnt;
%scan(&varnames, &i) %str(=) put(oldvar&i, best12.);
%end;
run;
%mend;
Here's part of the log showing the code generated by the macro.
NOTE: VARCNT=11 VARNAMES=YrMajor CrAtBat CrHits CrHome CrRuns CrRbi CrBB nOuts nAssts nError Salary
MPRINT(CHANGE): data baseball2 (drop= oldvar1 oldvar2 oldvar3 oldvar4 oldvar5 oldvar6 oldvar7 oldvar8 oldvar9 oldvar10 oldvar11);
MPRINT(CHANGE): set baseball (rename=( YrMajor=oldvar1 CrAtBat=oldvar2 CrHits=oldvar3 CrHome=oldvar4 CrRuns=oldvar5 CrRbi=oldvar6
CrBB=oldvar7 nOuts=oldvar8 nAssts=oldvar9 nError=oldvar10 Salary=oldvar11 ));
MPRINT(CHANGE): length YrMajor CrAtBat CrHits CrHome CrRuns CrRbi CrBB nOuts nAssts nError Salary $12;
MPRINT(CHANGE): YrMajor = put(oldvar1, best12.);
MPRINT(CHANGE): CrAtBat = put(oldvar2, best12.);
MPRINT(CHANGE): CrHits = put(oldvar3, best12.);
MPRINT(CHANGE): CrHome = put(oldvar4, best12.);
MPRINT(CHANGE): CrRuns = put(oldvar5, best12.);
MPRINT(CHANGE): CrRbi = put(oldvar6, best12.);
MPRINT(CHANGE): CrBB = put(oldvar7, best12.);
MPRINT(CHANGE): nOuts = put(oldvar8, best12.);
MPRINT(CHANGE): nAssts = put(oldvar9, best12.);
MPRINT(CHANGE): nError = put(oldvar10, best12.);
MPRINT(CHANGE): Salary = put(oldvar11, best12.);
MPRINT(CHANGE): run;