XSL quoting hell? - xslt

Question

I have a simple XML file that looks like this:
<bases xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
<marker>
<name>Sample 1</name>
<adr>Boston</adr>
<state>Mass</state>
<wiki>Link_1</wiki>
</marker>
<marker>
<name>Sample 2</name>
<adr>Essex</adr>
<state>Vermont</state>
</marker>
If there is a <wiki> element, I want to create an HTML link (an <a href..> tag) in the output. If there is no <wiki> element, then output only the name. Here's my XSL:
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="/">
<table><xsl:text>
</xsl:text>
<tr>
<th>Name</th>
<th>Address</th>
</tr>
<xsl:for-each select="bases/marker">
<xsl:sort select="name" />
<tr>
<td>
<xsl:if test="wiki != ''">
<a href="https://en.wikipedia.com/wiki/<xsl:value-of select='wiki'/>">
</xsl:if>
<xsl:value-of select="name"/>
<xsl:if test="wiki != ''">
</a>
</xsl:if>
</td>
</tr>
<td><xsl:value-of select="adr"/>, <xsl:value-of select="state"/></td>
<xsl:text>
</xsl:text>
</xsl:for-each>
</table>
</xsl:template>
</xsl:stylesheet>
I get a bunch of errors, starting with this one:
Unescaped '<' not allowed in attributes values
<a href="https://en.wikipedia.com/wiki/<xsl:value-of select='wiki'/>">
Help!

Answer 1

I am guessing you want to do:
XSLT 1.0
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="html"/>
<xsl:template match="/bases">
<table>
<tr>
<th>Name</th>
<th>Address</th>
</tr>
<xsl:for-each select="marker">
<xsl:sort select="name" />
<tr>
<td>
<xsl:if test="wiki">
<a href="https://en.wikipedia.com/wiki/{wiki}">
<xsl:value-of select="name"/>
</a>
</xsl:if>
</td>
<td>
<xsl:value-of select="adr"/>
<xsl:text>, </xsl:text>
<xsl:value-of select="state"/>
</td>
</tr>
</xsl:for-each>
</table>
</xsl:template>
</xsl:stylesheet>
To understand this, read about Attribute Value Templates.

Answer 2

Use an attribute value template:
<a href="https://en.wikipedia.com/wiki/{wiki}"/>
Otherwise, you could construct the value of the attribute like this:
<a>
<xsl:attribute name="href">https://en.wikipedia.com/wiki/<xsl:value-of select='wiki'/></xsl:attribute>
</a>
or like this:
<a>
<xsl:attribute name="href">
<xsl:value-of select="concat('https://en.wikipedia.com/wiki/', wiki)"/>
</xsl:attribute>
</a>