XSLT 2.0 sort using letters and numbers - xslt

Question

I have a sequence of strings that look like this:
B5 C10 C8 D11 D13 D3 D7 D9 E12 E8
I did the <xsl:perform-sort and <xsl:sort, based on the default data-type="text" and it's working correctly. But I would like to further sort so that after the letter the values are sorted numerically:
B5 C8 C10 D3 D7 D9 D11 D13 E8 E12
Any suggestions on how to do that? Thanks!
Edited to add my code:
<xsl:variable name="pns1" as="xs:string*">
<xsl:perform-sort select="distinct-values($combo1/*:pin/*:pkg[$pos]/*:pn/#n)">
<xsl:sort select="."/>
</xsl:perform-sort>
</xsl:variable>
<xsl:variable name="pns2" as="xs:string*">
<xsl:perform-sort select="$pns1">
<xsl:sort select="." data-type="number"/>
</xsl:perform-sort>
</xsl:variable>
<xsl:message select="$pns2"/>

Answer 1

Saxon allows you a parameter alphanumeric="yes" on a collation URI, see https://www.saxonica.com/html/documentation11/localization/unicode-collation-algorithm/ so e.g.
'B5 C10 C8 D11 D13 D3 D7 D9 E12 E8'
=> tokenize('\s+')
=> sort('http://www.w3.org/2013/collation/UCA?alphanumeric=yes')
gives
B5 C8 C10 D3 D7 D9 D11 D13 E8 E12
.
Online fiddle with Saxon XQuery (but XPath/XSLT support it the same): https://xqueryfiddle.liberty-development.net/jyH9Xvk.
Using numeric=yes;fallback=yes might even give better compatibility between the various Saxon editions (HE, PE, EE) and platforms (Java, .NET):
'B5 C10 C8 D11 D13 D3 D7 D9 E12 E8'
=> tokenize('\s+')
=> sort('http://www.w3.org/2013/collation/UCA?numeric=yes;fallback=yes')
or even SaxonJS.

Answer 2

Consider the following example:
XSLT 2.0
<xsl:stylesheet version="2.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:variable name="strings" select="('D13', 'B5', 'C10', 'E12', 'C8', 'D11', 'D3', 'E8', 'D7', 'D9')" />
<xsl:template match="/">
<result>
<xsl:perform-sort select="$strings">
<xsl:sort select="substring(., 1, 1)"/>
<xsl:sort select="substring(., 2)" data-type="number"/>
</xsl:perform-sort>
</result>
</xsl:template>
</xsl:stylesheet>
Result
<?xml version="1.0" encoding="UTF-8"?>
<result>B5 C8 C10 D3 D7 D9 D11 D13 E8 E12</result>