Power Query On Hand Inventory - powerbi

Question

I am trying to calculate rolling on hand inventory in power query at a week level for each location and product type.
In general the formula is:
Starting Inventory (System Data) + Receipts (Forecast) - Shipments (Forecast) + Returns (Forecast) = Ending Inventory (Forecast)
The format of the forecast data after pivoting Shipments, Receipts and Returns is:
Location, Product Type, Week, Shipments, Receipts, Returns
A, B, 1, 54, 69, 8
A, B, 2, 98, 12, 3
A, B, 3, 68, 50, 3
A, C, 1, 9, 58, 9
A, C, 2, 95, 20, 5
A, C, 3, 93, 42, 10
D, B, 1, 27, 87, 7
D, B, 2, 5, 2, 4
D, B, 3, 92, 19, 4
D, C, 1, 96, 17, 5
D, C, 2, 50, 50, 7
D, C, 3, 70, 95, 4
The format of the starting inventory is:
Location, Product Type, Starting Inventory
A, B, 116
A, C, 117
D, B, 108
D, C, 197
The desired result is:
Location, Product Type, Week, Shipments, Receipts, Returns, Ending Inventory
A, B, 1, 54, 69, 8, 139
A, B, 2, 98, 12, 3, 56
A, B, 3, 68, 50, 3, 41
A, C, 1, 9, 58, 9, 175
A, C, 2, 95, 20, 5, 105
A, C, 3, 93, 42, 10, 64
D, B, 1, 27, 87, 7, 175
D, B, 2, 5, 2, 4, 176
D, B, 3, 92, 19, 4, 107
D, C, 1, 96, 17, 5, 123
D, C, 2, 50, 50, 7, 130
D, C, 3, 70, 95, 4, 159
My internet searches make me think it would be done best with List.Generate, but I am not finding clear enough examples for me to follow.
So far I have only exported to excel and done the calculation there.
Any help would be greatly appreciated.

Answer 1

Try the code below.
Read the code comments and explore the Applied steps to better understand the algorithm
let
// Change Source= and Source2= lines to reflect the actual table names of the respective tables
//Read in the Inventory table
Source = Excel.CurrentWorkbook(){[Name="Inventory"]}[Content],
Inventory = Table.TransformColumnTypes(Source,{
{"Location", type text}, {"Product Type", type text}, {"Starting Inventory", Int64.Type}}),
//Read in the Data table
Source2 = Excel.CurrentWorkbook(){[Name="Data"]}[Content],
Data = Table.TransformColumnTypes(Source2,{
{"Location", type text}, {"Product Type", type text}, {"Week", Int64.Type}, {"Shipments", Int64.Type},
{"Receipts", Int64.Type}, {"Returns", Int64.Type}}),
// "Lookup" Starting inventory for each Location/Product type
// by doing a Table.Join
#"Join Starting Inventory" = Table.NestedJoin(Data,{"Location","Product Type"}, Inventory,{"Location","Product Type"},
"Joined", JoinKind.LeftOuter),
//Extract only the starting inventory column
#"Expanded Joined" = Table.ExpandTableColumn(#"Join Starting Inventory", "Joined", {"Starting Inventory"}, {"Starting Inventory"}),
//Group by Location and Product Type
//Then use List.Generate to calculate the Running Ending Inventory for each Location/Product type
#"Grouped Rows" = Table.Group(#"Expanded Joined", {"Location", "Product Type"}, {
{"Calc", (t)=>
let
Ending = List.Generate(
()=>[e=t[Starting Inventory]{0} + t[Receipts]{0} - t[Shipments]{0} + t[Returns]{0}, idx=0],
each [idx]< Table.RowCount(t),
each [e=[e] + t[Receipts]{[idx]+1} - t[Shipments]{[idx]+1} + t[Returns]{[idx]+1}, idx=[idx]+1],
each [e])
in
//Add the Ending Inventory List as a new column
// while removing the Starting Inventory column
Table.FromColumns(
Table.ToColumns(Table.RemoveColumns(t,"Starting Inventory")) & {Ending},
Table.ColumnNames(Data) & {"Ending Inventory"})}}),
//Expand the Grouped tables
#"Expanded Calc" = Table.ExpandTableColumn(#"Grouped Rows", "Calc",
List.RemoveFirstN(Table.ColumnNames(Data),2) & {"Ending Inventory"}),
//Set data types
typeIt = Table.TransformColumnTypes(#"Expanded Calc",
List.Transform(List.RemoveFirstN(Table.ColumnNames(#"Expanded Calc"),2), each {_, Int64.Type}))
in
typeIt