SAS COLUMN MERGING WITH UNEQUAL ROWS - - sas

Question

I need to create a 3rd table which will look like the following:
Data1:
policy
Risk
Premium
KOK1
002
150
KOK2
003
130
Data2:
Source
policy
Risk
Item1
ageofbuild
KOK1
002
3
yearofbuild
KOK1
002
5
Discount
KOK1
002
10%
Discount
KOK1
002
5%
ageofbuild
KOK2
003
4
yearofbuild
KOK2
003
6
Discount
KOK2
003
15%
Discount
KOK2
003
7%
Discount
KOK2
003
3%
Use dataset1 and dataset2 to create dataset 3?
Data3: (an extension of dataset1 with a discount column)
policy
Risk
Premium
Discount
KOK1
002
150
10%*5%
KOK2
003
130
15%*7%*3%
How do I set up a formula where policy and risk in data1 matches with policy and risk in dataset2 and grabs the discounts (multiplies them) and then creates a new table called data3 which is an extension of dataset1 with an additional column at the end called discount. Can someone please set up a code for me to achieve that?
I tried merging and using Hash tables but it did not work. I don't have much knowledge on SAS.

Answer 1

First thing is to convert your listings into actual datasets so we can see what TYPE of variables you have. So lets assume you meant you had data like this:
data policy ;
input policy $ Risk $ Premium ;
cards;
KOK1 002 150
KOK2 003 130
;
data rules ;
input Source :$20. policy $ Risk $ Item1 :8.2;
cards;
ageofbuild KOK1 002 3
yearofbuild KOK1 002 5
Discount KOK1 002 10
Discount KOK1 002 5
ageofbuild KOK2 003 4
yearofbuild KOK2 003 6
Discount KOK2 003 15
Discount KOK2 003 7
Discount KOK2 003 3
;
Now we just need to merge the two and concatenate the ITEM1 values for the observations where source is DISCOUNT. To make it LOOK like your output I made the new DISCOUNT variable a character string.
proc sort data=rules ;
by policy risk;
run;
proc sort data=policy;
by policy risk;
run;
data want;
merge policy (in=in1) rules (in=in2 where=(source='Discount'));
by policy risk;
length discount $30 ;
retain discount;
if in1 ;
if first.risk then discount=' ';
if in2 then discount=catx('*',discount,put(item1,percent5.));
if last.risk;
keep policy risk premium discount;
run;
Result
Obs policy Risk Premium discount
1 KOK1 002 150 10%*5%
2 KOK2 003 130 15%*7%*3%
You do not explain what multiplying discounts mean ( I doubt that combining a 5% discount with a 3% discount means you want 0.015% discount that the multiplication symbol in your listing implies). Do you want to add them? So 5% + 3% yields 8%? Compound them in some other way?