xquery or xslt to convert time hours to PT*H*M format - xslt

Question

I am new to XQuery and XSLT.
I'm looking for an XQuery or XQuery function to convert the timetotal i.e. 5 Hours to PT5H or 5.5 hours to PT5H30M
Not sure if XQuery can do that. If not any XSLT 1.0 function is ok too.

Answer 1

You can't define an xs:dayTimeDuration with a fractional number of hours, or minutes, but you can use a fractional number of seconds, so just multiply the hours by 3600 and create a duration in seconds:
xs:dayTimeDuration(
concat(
'PT',
$hours * 3600,
'S'
)
)
e.g.
let
$hours:= 5.551245
return
xs:dayTimeDuration(
concat(
'PT',
$hours * 3600,
'S'
)
)
returns: PT5H33M4.482S

Answer 2

Consider the following example:
XML
<input>
<hours>5</hours>
<hours>5.5</hours>
<hours>5.555</hours>
</input>
XSLT 1.0
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:template match="/input">
<output>
<xsl:for-each select="hours">
<xsl:variable name="seconds" select=". * 3600" />
<xsl:variable name="h" select="floor($seconds div 3600)"/>
<xsl:variable name="m" select="floor($seconds div 60) mod 60"/>
<xsl:variable name="s" select="$seconds mod 60"/>
<duration>
<xsl:text>PT</xsl:text>
<xsl:value-of select="$h"/>
<xsl:text>H</xsl:text>
<xsl:value-of select="$m"/>
<xsl:text>M</xsl:text>
<xsl:value-of select="$s"/>
<xsl:text>S</xsl:text>
</duration>
</xsl:for-each>
</output>
</xsl:template>
</xsl:stylesheet>
Result
<?xml version="1.0" encoding="UTF-8"?>
<output>
<duration>PT5H0M0S</duration>
<duration>PT5H30M0S</duration>
<duration>PT5H33M18S</duration>
</output>
This assumes the input value cannot be negative.
Do note that PT5H30Mand PT330M are equally valid expressions of the same duration - so you could just multiply the input value by 60 (assuming you only need precision to a minute).