Unexpected namespace declaration - xslt

Question

I'm porting old transformations to a new transformation platform (based on Saxon 9.9). I have an issue where the new platform creates slightly different results than the old platform (based on an ancient bug-ridden Oracle XSLT1+ implementation).
Consider the following source document:
<root xmlns="http://root.invalid">
<model xmlns="http://root.invalid">
<keys>
<id xmlns:foo="http://foo.invalid" foo:nil="true"/>
</keys>
<instance>
<id xmlns:foo="http://foo.invalid" foo:nil="true"/>
<whatever type="String">whatever</whatever>
</instance>
</model>
</root>
When the following transformation is applied:
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:root="http://root.invalid"
exclude-result-prefixes="root"
>
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>
<xsl:template match="node()|#*">
<xsl:copy>
<xsl:apply-templates select="node()|#*"/>
</xsl:copy>
</xsl:template>
<xsl:template match="root:id">
<id xmlns:foo="http://foo.invalid" foo:nil="true" type="String">1234</id>
</xsl:template>
</xsl:stylesheet>
The following (correct) output is generated:
<?xml version="1.0" encoding="UTF-8"?>
<root xmlns="http://root.invalid">
<model>
<keys>
<id xmlns:foo="http://foo.invalid" xmlns="" foo:nil="true" type="String">1234</id>
</keys>
<instance>
<id xmlns:foo="http://foo.invalid" xmlns="" foo:nil="true" type="String">1234</id>
<whatever type="String">whatever</whatever>
</instance>
</model>
</root>
The problem here is that in the new platform I get a xmlns="" namespace definition that didn't exists in the old platform (that is breaking existing consumers of the output transformation).
Can you explain why the xmlns="" appers here and is there any chance I could get:
<id xmlns:foo="http://foo.invalid" foo:nil="true" type="String">1234</id>
instead (with Saxon 9.9 based XSLT)?

Answer 1

If you want your result element(s) to be in that namespace then use e.g. xmlns="http://root.invalid" on the xsl:stylesheet or at least on the literal result id elements e.g. <id xmlns="http://root.invalid" .../>. Or use an xsl:copy and add the new attribute and text e.g. <xsl:copy><xsl:copy-of select="#*"/><xsl:attribute name="type">string</xsl:attribute>1234</xsl:copy> in your template matching the id elements.

Answer 2

You are creating the id element using the literal result element in the stylesheet:
<id xmlns:foo="http://foo.invalid" foo:nil="true" type="String">1234</id>
and the in-scope namespaces for this element also include
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:root="http://root.invalid"
The specification for literal result elements says that
(a) the expanded name (uri + local) of the element in the result tree must be the same as the expanded name of the literal result element: that is (no namespace, "id").
(b) the in-scope namespace bindings of the element in the result tree should include all in-scope namespaces of the literal result element, other than any excluded namespace bindings. The excluded namespace bindings are those for "xsl" and "root"; this leaves the binding for "foo" which is therefore present in the result.
The reason the xmlns="" is generated is that it is the only way to meet the requirement that the id element should be in no namespace. If it were not generated, the id element would be in the namespace "http://root.invalid".
If you don't want the xmlns="", that probably means you want the id element to be in the namespace "http://root.invalid", and you can achieve this by adding the declaration xmlns="http://root.invalid" to the literal result element in the stylesheet.
I can't comment on why the Oracle XDK got this wrong.

Answer 3

This rule, based on the answer by #MartinHonnen, produced the wanted results:
<xsl:template match="root:id">
<xsl:copy>
<xsl:copy-of select="#*"/>
<xsl:attribute name="type">string</xsl:attribute>
<xsl:text>1234</xsl:text>
</xsl:copy>
</xsl:template>