Converting multiple treatment records to one row - sas

Question

So I have this dataset. I basically need to concatenate all the con med treatments (CMTRT) so that they are horizontal so that each result for each day has only one row. My thinking here is to use PROC TRANSPOSE and create a prefix label CMTRT so I have cmtrt_1, cmtrt_2 etc so in the following data step I can use catx to combine into one variable. Is that right or is there a better way to do this?

Answer 1

Assuming you need the last value for RELCM, the following should give you the expected output.
proc sort data=have out=stage1; by subjid paramcd avalc avisit; run;
data stage2;
set stage1;
by subjid paramcd avalc avisit;
if first.avisit then
group_number+1;
run;
data want;
set stage2;
by subjid paramcd avalc avisit group_number;
retain _cmtrt;
*-- set large enough to accommodate the maximum number of records --*;
length _cmtrt $2000;
if first.group_number then
_cmtrt='';
_cmtrt=catx(', ', _cmtrt, cmtrt);
if last.group_number then
output;
rename _cmtrt=cmrtrt;
drop cmtrt group_number;
run;
Another method would be the DoW loop as pointed by #Richard's comment.
proc sort data=have out=stage1; by subjid paramcd avalc avisit; run;
data want(rename=(_cmtrt=cmtrt));
do _n_ = 1 by 1 until (last.avisit);
set stage1;
by subjid paramcd avalc avisit;
length _cmtrt $2000;
_cmtrt = catx(', ', _cmtrt, cmtrt);
end;
drop cmtrt;
run;
Assuming you don't need RELCM in your output dataset.
proc sort data=have out=stage1;
by subjid paramcd avalc avisit;
run;
proc transpose data=stage1 out=stage2;
by subjid paramcd avalc avisit;
var cmtrt;
run;
data want;
set stage2;
length cmtrt $2000;
cmtrt=catx(', ' , of col:);
drop _name_ col:;
run;