Tag the 6 first wording days of the month - powerbi

Question

I am trying to find a way to tag the 6 first wording days (Monday to Friday) of the month.
For example, for November I want:
Date
FlagDate
11/01/2021
True
11/02/2021
True
11/03/2021
True
11/04/2021
True
11/05/2021
True
11/06/2021
False
11/07/2021
False
11/08/2021
True
11/09/2021
False
11/10/2021
False
11/11/2021
False
11/12/2021
False
11/13/2021
False
11/14/2021
False
11/15/2021
False
11/16/2021
False
11/17/2021
False
11/18/2021
False
11/19/2021
False
11/20/2021
False
11/21/2021
False
and so on.

Answer 1

Here is M code that adds a column to your existing table.
It assumes that the column Name in your table is Date
It also assumes you have a List of the relevant holiday dates spanning at least the relevant time frame. I obtained the list from https://publicholidays.fr and buffered it to keep it from continuously downloading
See the comments in the M-Code to understand the algorithm
Note that there is no requirement that the Date column encompasses a full month. But if it starts on, for example, the 15th, there will be nothing in that month marked TRUE since the first6 are not there.
Assumption: Date column spans less than 1 year
If that is not the case, will need a different algorithm to create the first6 list.
M Code
//Before adding the "Flag" column enter this code to create a buffered list of working days in the months in the Date column
workingDays =
let
//generate list of all dates from beginning of first month to the last date listed
dts = List.Transform(
{Number.From(Date.StartOfMonth(#"Previous Step"[Date]{0}))..
Number.From(List.Max(#"Previous Step"[Date]))},each Date.From(_)),
//Using List.Generate, create a list of working days from the preceding list
//working days will be days that are Monday-Friday and NOT found in the list of Holiday dates
wdys = List.Generate(
()=>[wd=if Date.DayOfWeek(dts{0})>= Day.Monday
and Date.DayOfWeek(dts{0})<=Day.Friday
and not List.Contains(#"FR Holidays",dts{0}) then dts{0} else null,
idx = 0],
each [idx] < List.Count(dts),
each [wd=if Date.DayOfWeek(dts{[idx]+1})>= Day.Monday
and Date.DayOfWeek(dts{[idx]+1})<=Day.Friday
and not List.Contains(#"FR Holidays",dts{[idx]+1}) then dts{[idx]+1} else null,
idx = [idx]+1],
each [wd]),
//clean the wdys List by removing the Nulls
cleanList = List.RemoveNulls(wdys),
//create a list of the Months within the workday list
monthsInList= List.Distinct(List.Transform(cleanList, each Date.Month(_))),
//Use List.Accumulate to create lists of the first 6 working days in each month
first6 = List.Accumulate(monthsInList,{},
(state, current)=> state &
List.FirstN(List.Select(cleanList,each Date.Month(_)=current),6))
in List.Buffer(first6),
//Now add a column and set the flag if a Date in the date column is found in the first6 list
flagged = Table.AddColumn(#"Previous Step","FlagDate", each List.Contains(workingDays,[Date]), type logical)
in
flagged
filtered to show only dates marked True
M Code Edited to handle spans of more than one year
Change MonthsInList to include the year, and also Test for that in the List.Accumulate step
//Before adding the "Flag" column enter this code to create a buffered list of working days in the months in the Date column
workingDays =
let
//generate list of all dates from beginning of first month to the last date listed
dts = List.Transform(
{Number.From(Date.StartOfMonth(#"Previous Step"[Date]{0}))..
Number.From(List.Max(#"Previous Step"[Date]))},each Date.From(_)),
//Using List.Generate, create a list of working days from the preceding list
//working days will be days that are Monday-Friday and NOT found in the list of Holiday dates
wdys = List.Generate(
()=>[wd=if Date.DayOfWeek(dts{0})>= Day.Monday
and Date.DayOfWeek(dts{0})<=Day.Friday
and not List.Contains(#"FR Holidays",dts{0}) then dts{0} else null,
idx = 0],
each [idx] < List.Count(dts),
each [wd=if Date.DayOfWeek(dts{[idx]+1})>= Day.Monday
and Date.DayOfWeek(dts{[idx]+1})<=Day.Friday
and not List.Contains(#"FR Holidays",dts{[idx]+1}) then dts{[idx]+1} else null,
idx = [idx]+1],
each [wd]),
//clean the wdys List by removing the Nulls
cleanList = List.RemoveNulls(wdys),
//create a list of the Months within the workday list
monthsInList= List.Distinct(List.Transform(cleanList, each Date.ToText(_,"yyyy-MM"))),
//Use List.Accumulate to create lists of the first 6 working days in each month
first6 = List.Accumulate(monthsInList,{},
(state, current)=> state &
List.FirstN(List.Select(cleanList,each Date.ToText(_,"yyyy-MM")=current),6))
in List.Buffer(first6),
//Now add a column and set the flag if a Date in the date column is found in the first6 list
flagged = Table.AddColumn(#"Previous Step","FlagDate", each List.Contains(workingDays,[Date]), type logical)
in
flagged

Answer 2

You can create a custom column with DAX with the following formula
= CONTAINS(TOPN(6,FILTER('Table',WEEKDAY('Table'[Date],2)<6)),'Table'[Date],'Table'[Date])
You can update TopN(6 to accordingly update the number of first working days