Loop through comma separated macro variable in SAS - sas

Question

I'd like to loop through a comma separated macro variable like the following, which I also use in the where condition of a proc sql statement:
%let example = (1, 2, 3, 4)
I found the following syntax which almost covers my case:
%macro px;
%let value = 1 2 3 4;
%local i next_value;
%let i=1;
%do %while (%scan(&value, &i) ne );
%let next_value = %scan(&value, &i);
%put&=next_value;
%let i = %eval(&i + 1);
%end;
%mend;
%px;
Unforunately, I don't know how to modify that syntax such that it works for my example. If I add commas to the 'value' variable I get the error "Macro function %SCAN has too many arguments" which doesn't make sense to me.

Answer 1

User str% to wrap string. And you can simplify code:
%macro px;
%let value = (1, 2, 3, 4);
%let value = %sysfunc(compress(&value, %str(%(%))));
%let value = %str(%bquote(&value));
%do mvI=1 %to %sysfunc(countw(&value, %str(,)));
%let next_value = %scan(&value, &mvI, %str(,));
%put&=next_value;
%end;
%mend;
%px;

Answer 2

You need to protect the comma so that %SCAN() does not see it as separator between the arguments. If you used the actual EXAMPLE value your existing code would work because the parentheses enclosing the comma separated list of numbers would do that.
Note that since you didn't tell %SCAN() what delimiter characters to use the parentheses commas and spaces are all considered delimiters.
If your value does not have the parentheses around it then you can protect the comma with macro quoting.
%let value=%quote(&value);
If you pass the value to the macro as an actual parameter, then the onus of ensuring the commas are protected will fall on the code that calls the macro. Also there is no need write code to increment the loop counter. The %DO loop supports that, just use the COUNTW() function to determine the upper bound.
%macro px(list);
%local i next_value;
%do i=1 %to %sysfunc(countw(&list));
%let next_value = %scan(&list, &i);
%put &=i &=next_value;
%end;
%mend;
%let example = (1, 2, 3, 4);
%px( &example );
%px( %str(1,2,3,4) );