I'm trying to convert some code from rasterization shader to a raytracing shader - glsl

Question

From what I seen the dFdx and dFdy functions don't run in the closet hit shader. So I have to convert to something like it. I'd think this the equivlent but I'm not getting the same result. Am I missing something?
From the raster shader that I got from LearnOpenGl https://learnopengl.com/PBR/Lighting :
vec3 getNormalFromMap()
{
vec3 tangentNormal = texture(normalMap, TexCoords).xyz * 2.0 - 1.0;
vec3 Q1 = dFdx(WorldPos);
vec3 Q2 = dFdy(WorldPos);
vec2 st1 = dFdx(TexCoords);
vec2 st2 = dFdy(TexCoords);
vec3 N = normalize(Normal);
vec3 T = normalize(Q1*st2.t - Q2*st1.t);
vec3 B = -normalize(cross(N, T));
mat3 TBN = mat3(T, B, N);
return normalize(TBN * tangentNormal);
}
My attempted recreation of it:
vec3 getNormalFromMap(MaterialInfo material, Vertex vertex)
{
vec3 T = normalize(mat3(meshProperties[gl_InstanceCustomIndexEXT].ModelTransform * MeshTransform[gl_InstanceCustomIndexEXT].Transform) * vec3(vertex.tangent));
vec3 B = normalize(mat3(meshProperties[gl_InstanceCustomIndexEXT].ModelTransform * MeshTransform[gl_InstanceCustomIndexEXT].Transform) * vec3(vertex.BiTangant));
vec3 N = normalize(mat3(meshProperties[gl_InstanceCustomIndexEXT].ModelTransform * MeshTransform[gl_InstanceCustomIndexEXT].Transform) * vertex.normal);
mat3 TBN = transpose(mat3(T, B, N));
vec3 normal = texture(TextureMap[material.NormalMapID], vertex.uv).xyz;
normal = normalize(normal * 2.0 - 1.0);
return TBN * normal;
}
On the comments from the code it says it should be able to be done the normal way so I'm just trying figure if my conversion code is wrong of if the problem is somewhere else in the shader.
https://learnopengl.com/code_viewer_gh.php?code=src/6.pbr/1.2.lighting_textured/1.2.pbr.fs
// ----------------------------------------------------------------------------
// Easy trick to get tangent-normals to world-space to keep PBR code simplified.
// Don't worry if you don't get what's going on; you generally want to do normal
// mapping the usual way for performance anways; I do plan make a note of this
// technique somewhere later in the normal mapping tutorial.

Answer 1

Never mind I figured it out.
Turns out that I was transposing the TBN matix when I should have been and forgot to normalize the TBN * normal.
Old Code:
vec3 getNormalFromMap(MaterialInfo material, Vertex vertex)
{
vec3 T = normalize(mat3(meshProperties[gl_InstanceCustomIndexEXT].ModelTransform * MeshTransform[gl_InstanceCustomIndexEXT].Transform) * vec3(vertex.tangent));
vec3 B = normalize(mat3(meshProperties[gl_InstanceCustomIndexEXT].ModelTransform * MeshTransform[gl_InstanceCustomIndexEXT].Transform) * vec3(vertex.BiTangant));
vec3 N = normalize(mat3(meshProperties[gl_InstanceCustomIndexEXT].ModelTransform * MeshTransform[gl_InstanceCustomIndexEXT].Transform) * vertex.normal);
mat3 TBN = transpose(mat3(T, B, N));
vec3 normal = texture(TextureMap[material.NormalMapID], vertex.uv).xyz;
normal = normalize(normal * 2.0 - 1.0);
return TBN * normal;
}
Fixed Code:
vec3 getNormalFromMap(MaterialInfo material, Vertex vertex)
{
vec3 T = normalize(mat3(meshProperties[gl_InstanceCustomIndexEXT].ModelTransform * MeshTransform[gl_InstanceCustomIndexEXT].Transform) * vec3(vertex.tangent));
vec3 B = normalize(mat3(meshProperties[gl_InstanceCustomIndexEXT].ModelTransform * MeshTransform[gl_InstanceCustomIndexEXT].Transform) * vec3(vertex.BiTangant));
vec3 N = normalize(mat3(meshProperties[gl_InstanceCustomIndexEXT].ModelTransform * MeshTransform[gl_InstanceCustomIndexEXT].Transform) * vertex.normal);
mat3 TBN = mat3(T, B, N);
vec3 normal = texture(TextureMap[material.NormalMapID], vertex.uv).xyz;
normal = normalize(normal * 2.0 - 1.0);
return normalize(TBN * normal);
}