Hiding block when the next sibiling is empty with XSL-FO - xslt

Question

I'm using Apache FOP to generate reports, my template's like this:
<xsl:template match="LOGO">
<xsl:param name="imgLogo">
<xsl:value-of select="IMG" />
</xsl:param>
<fo:external-graphic content-height="scale-to-fit"
height="50pt" src="{$imgLogo}" />
</xsl:template>
<xsl:template match="MYREPORT">
<fo:block>
<xsl:apply-templates select="LOGO" />
</fo:block>
<fo:block>
<xsl:value-of select="PAG_1" />
</fo:block>
<fo:block page-break-before="always">
<xsl:apply-templates select="LOGO" />
</fo:block>
<fo:block>
<xsl:value-of select="PAG_2" />
</fo:block>
<fo:block page-break-before="always">
<xsl:apply-templates select="LOGO" />
</fo:block>
<fo:block>
<xsl:value-of select="PAG_3" />
</fo:block>
</xsl:template>
I've to hide the "LOGO" block (before each PAGE) if the next sibiling block (PAGE) is empty.
For example, with the following input:
<MYREPORT>
<LOGO>
<IMG>data:image/png;base64,[cutted]</IMG>
</LOGO>
<PAG_1>Page 1</PAG_1>
<PAG_2>Page 2</PAG_2>
</MYREPORT>
It should print:
LOGO
Page 1
(new page)
LOGO
Page 2
It's printing the following instead:
LOGO
Page 1
(new page)
LOGO
Page 2
(new page)
LOGO
Any idea? Thanks

Answer 1

The most direct way is to put an xsl:if around the code for PAG_3:
<xsl:template match="MYREPORT">
<fo:block>
<xsl:apply-templates select="LOGO" />
</fo:block>
<fo:block>
<xsl:value-of select="PAG_1" />
</fo:block>
<fo:block page-break-before="always">
<xsl:apply-templates select="LOGO" />
</fo:block>
<fo:block>
<xsl:value-of select="PAG_2" />
</fo:block>
<xsl:if test="PAG_3">
<fo:block page-break-before="always">
<xsl:apply-templates select="LOGO" />
</fo:block>
<fo:block>
<xsl:value-of select="PAG_3" />
</fo:block>
</xsl:if>
</xsl:template>
An alternative approach (which I would use) is to use xsl:apply-templates to select the PAG_* elements so that a result is generated only for elements that exist:
<xsl:template match="MYREPORT">
<xsl:apply-templates select="PAG_1 | PAG_2 | PAG_3" />
</xsl:template>
<xsl:template match="PAG_1 | PAG_2 | PAG_3">
<fo:block>
<xsl:if test="position() != 1">
<xsl:attribute name="page-break-before">always</xsl:attribute>
</xsl:if>
<xsl:apply-templates select="../LOGO" />
</fo:block>
<fo:block>
<xsl:apply-templates />
</fo:block>
</xsl:template>