XSLT1.0 copy all nodes and add a few similar nodes - xslt

Question

I have xml and I would like to add a few elements, but without affecting the other elements that are already there. The order of the elements is not important. But one of the new elements is not being added, how to fix it?
Input XML
<?xml version="1.0" encoding="utf-8"?>
<root>
<InterchangeHeader>InterchangeHeader</InterchangeHeader>
<SG0>
<UNH>UNH</UNH>
<BGM>BGM</BGM>
<DTM>DTM</DTM>
<SG26>
<LIN>
<E1082>000010</E1082>
<C212>
<E7143>SRV</E7143>
</C212>
</LIN>
<PIA>
<E4347>1</E4347>
<C212>
<E7140>000010</E7140>
<E7143>IN</E7143>
</C212>
</PIA>
<QTY>
<C186>
<E6063>21</E6063>
<E6060>2100.000</E6060>
<E6411>EA</E6411>
</C186>
</QTY>
<QTY>
<C186>
<E6063>170</E6063>
<E6060>2100.000</E6060>
<E6411>EA</E6411>
</C186>
</QTY>
</SG26>
<SG26>
<LIN>
<E1082>000020</E1082>
<C212>
<E7143>SRV</E7143>
</C212>
</LIN>
<PIA>
<E4347>1</E4347>
<C212>
<E7140>000020</E7140>
<E7143>IN</E7143>
</C212>
</PIA>
<QTY>
<C186>
<E6063>21</E6063>
<E6060>2100.000</E6060>
<E6411>EA</E6411>
</C186>
</QTY>
<QTY>
<C186>
<E6063>170</E6063>
<E6060>0.000</E6060>
<E6411>EA</E6411>
</C186>
</QTY>
</SG26>
<SG26>
<LIN>
<E1082>000030</E1082>
<C212>
<E7143>SRV</E7143>
</C212>
</LIN>
<PIA>
<E4347>1</E4347>
<C212>
<E7140>000030</E7140>
<E7143>IN</E7143>
</C212>
</PIA>
<QTY>
<C186>
<E6063>21</E6063>
<E6060>2100.000</E6060>
<E6411>EA</E6411>
</C186>
</QTY>
<QTY>
<C186>
<E6063>170</E6063>
<E6060>1900.000</E6060>
<E6411>EA</E6411>
</C186>
</QTY>
</SG26>
<UNS>
<E0081>S</E0081>
</UNS>
</SG0>
<InterchangeTrailer>InterchangeTrailer</InterchangeTrailer>
</root>
MY XSLT In the first part, I copy everything, and then I try to change
<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:msxml="urn:schemas-microsoft-com:xslt" xmlns:ext="urn:ext" exclude-result-prefixes="ext msxml">
<xsl:output method="xml" indent="yes" encoding="utf-8"/>
<xsl:template match="node()|#*">
<xsl:copy>
<xsl:apply-templates select="node()|#*"/>
</xsl:copy>
</xsl:template>
<xsl:template match="SG26[not(QTY/C186/E6063=59)]">
<xsl:copy>
<xsl:apply-templates select="#* | node()"/>
<QTY>
<C186>
<E6063>59</E6063>
<E6060>
<xsl:value-of select="'status'"/>
</E6060>
<E6411>
<xsl:value-of select="'status'"/>
</E6411>
</C186>
</QTY>
</xsl:copy>
</xsl:template>
<xsl:template match="SG26[not(QTY/C186/E6063=60)]">
<xsl:copy>
<xsl:apply-templates select="#* | node()"/>
<QTY>
<C186>
<E6063>60</E6063>
<E6060>
<xsl:value-of select="'status2'"/>
</E6060>
<E6411>
<xsl:value-of select="'status2'"/>
</E6411>
</C186>
</QTY>
</xsl:copy>
</xsl:template>
</xsl:stylesheet>
I would like to add a few elements, but without affecting the other elements that are already there. The order of the elements is not important. But one of the new elements is deleted, how can I fix it?

Answer 1

Perhaps you can solve it as follows:
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:msxml="urn:schemas-microsoft-com:xslt" xmlns:ext="urn:ext" exclude-result-prefixes="ext msxml">
<xsl:param name="elements-to-add-rtf">
<QTY>
<C186>
<E6063>59</E6063>
<E6060>status</E6060>
<E6411>status</E6411>
</C186>
</QTY>
<QTY>
<C186>
<E6063>60</E6063>
<E6060>status2</E6060>
<E6411>status2</E6411>
</C186>
</QTY>
</xsl:param>
<xsl:variable name="elements-to-add" select="msxml:node-set($elements-to-add-rtf)"/>
<xsl:output method="xml" indent="yes" encoding="utf-8"/>
<xsl:strip-space elements="*"/>
<xsl:template match="node()|#*">
<xsl:copy>
<xsl:apply-templates select="node()|#*"/>
</xsl:copy>
</xsl:template>
<xsl:template match="SG26">
<xsl:copy>
<xsl:apply-templates select="#* | node()"/>
<xsl:apply-templates select="$elements-to-add/QTY[not(C186/E6063 = current()/QTY/C186/E6063)]"/>
</xsl:copy>
</xsl:template>
</xsl:stylesheet>
Note that the XSLT 1 specific use of the namespace for the extension function node-set is processor dependent, as your code declared the prefix and namespace that works with Microsoft processors I assumed you are working with one of them and used that prefix.