Remove duplicate elements from a tcl List - list

Question

I have a list variable $a which has below as value.
{1|Katy|347689 2|Jerry|467841 1|Katy|987654}
I am trying to remove duplicated on the basis of
1|Katy avoiding the userid available at last.
Expected output should be.
{1|Katy|347689 2|Jerry|467841}
I tried using lsort -unique option. Seems like this does not work properly in my case.
set uniqueElement [lsort -unique $a]
Also ,just for illustrative purpose the list values are shown as having 3 values. I have more than 500 in the same format. I am trying to remove duplicates on the basis of 1|Katy while avoiding the userid.
Can suggest any other way I can resolve this to remove duplicates in this format for a list?

Answer 1

This is a little bit tricky as you have parts that are to be ignored when deduplicating. Because of that, lsort -unique is not the right tool. Instead, you want to use a dictionary.
# Identify the values that each key maps to
set d {}
foreach entry $inputList {
# Alternatively, use regular expressions to do the entry parsing
set value [join [lassign [split $entry "|"] a b] "|"]
set key [string cat $a "|" $b]
dict lappend d $key $value
}
# Build the output list using the first value each key maps to
set outputList {}
dict for {key values} $d {
lappend outputList [string cat $key "|" [lindex $values 0]]
}
That makes outputList hold the value you are seeking. (You don't need to use string cat, but I think it makes the code clearer in this case.)

Answer 2

You can still use lsort -unique by manipulating your initial list beforehand:
set new_format_list [join [split $a "|"] ]
set new_format_sorted_list [lsort -unique -stride 3 $new_format_list]
foreach {el1 el2 el3} $new_format_sorted_list {
lappend newlist "$el1|$el2|$el3"
}
puts "$newlist"
The variable new_format_list is now a flat list of all elements of your entry list (here, 9 elements). The | have been used to split the element of your initial list.
The variable new_format_sorted_list actually remove duplicate. Stride 3 means elements of the list will be check 3 by 3. Only the 1st of 3 is used for comparison.
The foreach is used to create a list with the same format that is used in entry. lappend is able to create variable if it doen't exist.
check the result
Normally, you should get what you want.
Edit based on nurdglaw pertinent comment
# entry list
set original_list {1|Katy|347689 2|Jerry|467841 1|Katy|987654}
set temp_list [join [split $original_list "|"] ]
# dirty method
# separate the third element from the first two
# then the string of the first two elements is the id for uniqueness
foreach {l1 l2 l3} $temp_list {
append new_format_list "$l1|$l2 $l3 " ;# use string to make a tcl list
#the space at this end is mandatory
}
set new_format_sorted_list [lsort -unique -stride 2 $new_format_list]
foreach {el1 el2} $new_format_sorted_list {
lappend cleanlist "$el1|$el2"
}
puts "$cleanlist"