How can I tidy my relative references using CMake? - c++

Question

I'm quite new to C++ and trying to get to grips with CMake and referencing files elsewhere in the project. My references within my test file currently looks like this:
#include "catch.hpp"
#include "../../src/containers/containers.h"
How can I tidy this up using CMake to have the following?
#include "catch.hpp"
#include "src/containers/containers.h"
My folder structure is as follows:
Project
├── lib
│ └── Catch2
│ └── catch.hpp
├── src
│ ├── containers
│ │ ├── containers.cpp
│ │ └── containers.h
│ └── CMakeLists.cpp
├── tests
│ ├── bin
│ ├── containers
│ │ └── test_containers.html
│ ├── CMakeLists.cpp
│ └── tests_main.cpp
├── CMakeLists.cpp
└── main.cpp
And my current CMakeLists.txt in ./tests/ is as follows:
set(CATCH_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/lib/Catch2")
add_library(Catch INTERFACE)
target_include_directories(Catch INTERFACE ${CATCH_INCLUDE_DIR})
set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_SOURCE_DIR}/tests/bin)
add_executable(test_containers tests_main.cpp containers/test_containers.cpp)
target_link_libraries(test_containers Catch containers)
add_test(NAME test_containers COMMAND test_containers)
enable_testing()
I include the following directories in my base CMakeLists.txt:
add_subdirectory(src)
add_subdirectory(tests)
And in src, I make containers a library:
add_library(containers STATIC
containers/containers.cpp
containers/containers.h)

Answer 1

Adding the line target_include_directories(containers PUBLIC "${CMAKE_SOURCE_DIR}/src") solved the issue and allowed my references to be reduced as desired.

Answer 2

following my comments, supposing you want to use #include "containers.h"
target_include_directories(containers
PUBLIC
$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/containers>
$<INSTALL_INTERFACE:include/containers>)
set_target_properties(containers PROPERTIES
PUBLIC_HEADER containers/containers.h)
# Install
include(GNUInstallDirs)
install(TARGETS containers
EXPORT ${PROJECT_NAME}Targets
PUBLIC_HEADER DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/containers
# ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
# LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
# RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
)
ref:
https://cmake.org/cmake/help/latest/command/target_include_directories.html
https://cmake.org/cmake/help/latest/variable/CMAKE_CURRENT_SOURCE_DIR.html
https://cmake.org/cmake/help/latest/module/GNUInstallDirs.html
https://cmake.org/cmake/help/latest/command/install.html#targets