Calculate number of months from 02 different years in power BI - powerbi

Question

Im calculating number of months in two different years.That means if i select date filter from 2020 jan 1st to todate i need to show 2020 has 12 months and 2021 has 02 months todate from january.i want to show 02 cards seperately to show months.is there a way to do this? I tries Datediff. But it shows months count form 2020 to todate. Can someone help me to get this?
Thank

Answer 1

Assuming you only have a table containing only the 'Date'[Date] column, like generated by
Date = CALENDAR("2019-01-01", "2021-12-31")
you can write two measures, one to get the months of the last year in the selection and of the previous one
# Months =
VAR CurrentYear = YEAR( MAX( 'Date'[Date] ) )
VAR CurrentYearDates = FILTER( 'Date', YEAR( 'Date'[Date] ) = CurrentYear )
VAR Months = SELECTCOLUMNS( CurrentYearDates, "Month", MONTH( 'Date'[Date] ) )
RETURN
COUNTROWS( DISTINCT ( Months ) )
# Months PY =
VAR PY = YEAR( MAX( 'Date'[Date] ) ) - 1
VAR PYDates = FILTER( 'Date', YEAR( 'Date'[Date] ) = PY )
VAR Months = SELECTCOLUMNS( PYDates, "Month", MONTH( 'Date'[Date] ) )
RETURN
COUNTROWS( DISTINCT ( Months ) )
this allows to assign a measure per card
This could be simplified with a Date table with Year and Month
Date =
ADDCOLUMNS (
CALENDAR ( "2019-01-01", "2021-12-31" ),
"Year", YEAR ( [Date] ),
"Month", MONTH ( [Date] )
)
# Months =
VAR CurrentYear = YEAR( MAX( 'Date'[Date] ) )
RETURN
CALCULATE( DISTINCTCOUNT( 'Date'[Month] ), 'Date'[Year] = CurrentYear )
# Months PY =
VAR PY = YEAR( MAX( 'Date'[Date] ) ) - 1
RETURN
CALCULATE( DISTINCTCOUNT( 'Date'[Month] ), 'Date'[Year] = PY )