Editing hbar graph (Stata) - stata

Question

My code below produces the graph attached. However, I am trying to add two adjustments but with no luck.
1- I would like to organize the Y axis where for all industries November comes before December, rather than being arranged by which month had more jobs as in the current graph.
2- I also tried adding labels to the Y axis where it only says "Nov" & "Dec", without the additional text, and while Stata does not produce any errors, it is not changing the graph.
preserve
drop if total_jobs_industry<15
graph hbar (count) total_jobs_industry, over(month) over(industry, sort(1)) subtitle("Jobs by Industry and month", span)
restore
I know that I can change the graph with tiny details manually in Stata, but I prefer automating the process if possible.
Data example:
Example generated by -dataex-. To install: ssc install dataex
clear
input float total_jobs_industry str39 industry str8 month
11 "Architectural & Engineering Services" "Nov_2020"
11 "Architectural & Engineering Services" "Nov_2020"
11 "Architectural & Engineering Services" "Dec_2020"
11 "Architectural & Engineering Services" "Dec_2020"
11 "Architectural & Engineering Services" "Nov_2020"
11 "Architectural & Engineering Services" "Dec_2020"
11 "Architectural & Engineering Services" "Dec_2020"
11 "Architectural & Engineering Services" "Nov_2020"
38 "Computer Hardware & Software" "Dec_2020"
12 "Consulting" "Dec_2020"
63 "" "Dec_2020"
32 "IT Services" "Dec_2020"
32 "IT Services" "Nov_2020"
38 "Computer Hardware & Software" "Nov_2020"
12 "Aerospace & Defense" "Nov_2020"
12 "Accounting" "Nov_2020"
12 "Accounting" "Dec_2020"
When I ran with sum, instead of count, I get the graph below:
preserve
drop if total_jobs_industry<15
graph hbar (sum) total_jobs_industry, over(month) over(industry, sort(1)) subtitle("Jobs by Industry and month", span)
restore
Furthermore, this is how I create the variable to the count the number of jobs per industry:
// The variable id contains observation number running from 1 to X and nt is the total number of observations
generate id = _n
generate nt = _N
// Sorting by inudstry. Now n1 is the observation number within each Industry group and total_jobs_industry is the total number of observations for each Industry group.
sort industry
by industry: generate n1 = _n
by industry: generate total_jobs_industry = _N
order total_jobs_industry, a(industry)

Answer 1

This is a very puzzling question. The following list of reasons is not complete.
The post seems to mix old and new versions of itself and isn't consistent. You can not reasonably expect us to decode such a meandering story reliably. The standard here is to present a minimal verifiable example, and that standard is not being met by this thread. See guidance here.
Neither of the graphs shown correspond to the data given.
It is hard for me to believe that (count) makes sense for your data. As said, it counts non-missing values, but your key variable appears to be total_count_industry. On the other hand, working variously with (sum) and the number of observations seems to confuse quite different kinds of calculations.
There appear to be duplicate observations in your example data.
You state that you ' also tried adding labels to the Y axis where it only says "Nov" & "Dec" ' but nothing in your code shows any such attempt to comment on.
You're expecting Nov_2020 to sort before Dec_2020, which won't happen because so far as Stata is concerned it is just a string variable, so the fact that D sorts before N is paramount. This is the reason December sorts before January, and it's nothing to do with sorting on industry values, which affects only the ordering of the groups of bars. You're not making use of Stata's functionality for date variables.
I doubt that I can make sense of any of these problems except the last. It seems to be a limitation of graph hbar that it ignores time variable display formats, so I used value labels to ensure that Nov and Dec sort in the order you wish.
clear
input float total_jobs_industry str39 industry str8 month
11 "Architectural & Engineering Services" "Nov_2020"
11 "Architectural & Engineering Services" "Nov_2020"
11 "Architectural & Engineering Services" "Dec_2020"
11 "Architectural & Engineering Services" "Dec_2020"
11 "Architectural & Engineering Services" "Nov_2020"
11 "Architectural & Engineering Services" "Dec_2020"
11 "Architectural & Engineering Services" "Dec_2020"
11 "Architectural & Engineering Services" "Nov_2020"
38 "Computer Hardware & Software" "Dec_2020"
12 "Consulting" "Dec_2020"
63 "" "Dec_2020"
32 "IT Services" "Dec_2020"
32 "IT Services" "Nov_2020"
38 "Computer Hardware & Software" "Nov_2020"
12 "Aerospace & Defense" "Nov_2020"
12 "Accounting" "Nov_2020"
12 "Accounting" "Dec_2020"
end
duplicates drop
gen mdate = monthly(month, "MY")
levelsof mdate, local(months)
tokenize "`c(Mons)'"
foreach m of local months {
local month = month(dofm(`m'))
label def mdate `m' "``month''", modify
}
label val mdate mdate
set scheme s1color
graph hbar (asis) total_jobs_industry, over(mdate) over(industry, sort(1) descending)