xslt group by function or append to array - xslt

Question

I have collection of items:
<items>
<result>
<item>
<product_name>some description</product_name>
</item>
<item>
<product_name>some similar description</product_name>
</item>
<item>
<product_name>other product size 1</product_name>
</item>
<item>
<product_name>other product size 2</product_name>
</item>
</result>
</items>
I also have some external function strdist:string-distance that compares previous product to current one and if there is some match then it returns true. Based on this returned value I'd like to:
add the current element of for-each to the group of previous element when returned value is true
close previous group, create a new group and add current element of for-each loop to it when returned value is false
I'm little bit struggling with the process of how to create the groups and add there elements in for-loop.
Here is my template
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:strdist="http://example.com/string-distance"
exclude-result-prefixes="strdist">
<xsl:output method="xml" indent="yes" omit-xml-declaration="yes"/>
<xsl:template match="/">
<xsl:variable name="items" as="element()*">
<xsl:perform-sort select="items/result/item">
<xsl:sort select="./product_name"/>
</xsl:perform-sort>
</xsl:variable>
<xsl:variable name="groupedItems" as="element()*">
<groups>
<xsl:for-each select="$items">
<xsl:variable name="position" select="position()"/>
<xsl:variable name="currentProductName" select="./product_name/text()"/>
<xsl:choose>
<xsl:when test="$position -1 = 0">
<xsl:element name="group"/>
<xsl:message select="concat($position, ' # ', $currentProductName)"/>
</xsl:when>
<xsl:when test="$position -1 > 0">
<xsl:variable name="previousProductName"
select="$items[position() = $position -1]/product_name/text()"/>
<xsl:message
select="concat($position, ' # ', $previousProductName, ' # ', $currentProductName)"/>
<xsl:message select="strdist:string-distance($previousProductName, $currentProductName)"/>
</xsl:when>
</xsl:choose>
</xsl:for-each>
</groups>
</xsl:variable>
<xsl:message select="$groupedItems" />
</xsl:template>
</xsl:stylesheet>
Finally I'd like to have something like this:
<items>
<result>
<group>
<item>
<product_name>some description</product_name>
</item>
<item>
<product_name>some similar description</product_name>
</item>
</group>
<group>
<item>
<product_name>other product size 1</product_name>
</item>
<item>
<product_name>other product size 2</product_name>
</item>
</group>
</result>
</items>
I'm using xslt 2.0 with saxon-he 10.3.

Answer 1

Here is the example using for-each-group group-starting-with and a sample function:
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:xs="http://www.w3.org/2001/XMLSchema"
xmlns:mf="http://example.com/mf"
exclude-result-prefixes="#all"
version="3.0">
<xsl:mode on-no-match="shallow-copy"/>
<xsl:output method="xml" indent="yes"/>
<xsl:function name="mf:string-distance" as="xs:boolean">
<xsl:param name="name1" as="xs:string"/>
<xsl:param name="name2" as="xs:string"/>
<xsl:sequence select="tokenize($name1)[1] = tokenize($name2)[1]"/>
</xsl:function>
<xsl:template match="result">
<xsl:copy>
<xsl:for-each-group select="item" group-starting-with="item[not(mf:string-distance(product_name, preceding-sibling::item[1]/product_name))]">
<group>
<xsl:apply-templates select="current-group()"/>
</group>
</xsl:for-each-group>
</xsl:copy>
</xsl:template>
</xsl:stylesheet>
Seems to give the wanted result at https://xsltfiddle.liberty-development.net/bEJbVrR.