Why am I getting SAS ERROR 22-322 syntax error [closed] - sas

Question

Closed. This question is not reproducible or was caused by typos. It is not currently accepting answers.
This question was caused by a typo or a problem that can no longer be reproduced. While similar questions may be on-topic here, this one was resolved in a way less likely to help future readers.
Closed 2 years ago.
Improve this question
My codes are as below, the problem comes from codes after the note /now you can apply your logic to the dataset/, the problem in the log is Testwyf.. and ERROR 22-322: syntax error, I don't know why there are two dots, and I want to make it like libname.memname, but it just doesn't work.
Hoping someone could help me solve this problem.
input dataset Testwyf.varlst:
Error update:
Error:
MPRINT(LOOPOVERDATASETS): data Testwyf." ."N(drop=TradingTime);
NOTE: Line generated by the macro variable "INDSN".
1 .." ."N
-
22
200
enter image description here
ERROR 22-322: Syntax error, expecting one of the following: a name, a quoted string, ;, CUROBS, END, INDSNAME, KEY, KEYRESET,
KEYS, NOBS, OPEN, POINT, DATA, LAST, NULL.
ERROR 200-322: The symbol is not recognized and will be ignored.
%macro loopOverDatasets();
/*imho good practice to declare macro variables of a macro locally*/
%local datasetCount iter inLibref inMember outLibref;
/*get number of datasets*/
proc sql noprint;
select count(*)
into :datasetCount
from Testwyf.Varlst;
quit;
/*initiate loop*/
%let iter=1;
%do %while (&iter.<= &datasetCount.);
/*get libref and dataset name for dataset you will work on during this iteration*/
data _NULL_;
set Testwyf.Varlst (firstobs=&iter. obs=&iter.); *only read 1 record;
*write the libname and dataset name to the macro variables;
call symputx("inLibref",strip(libname));
call symputx("inMember",nliteral(memname));
call symputx("outLibref","Testwyf");
*NOTE: i am always mortified by the chance of trailing blanks torpedoing my code, hence the strip function;
run;
/*now you can apply your logic to the dataset*/
%let indsn = &inLibref..&inMember.;
%let outdsn = &outLibref..&inMember.;
data &outdsn.(drop=TradingTime);
set &indsn.(keep=Symbol ShortName TradingTime LastPrice OpenPrice);
Date=put(TradingTime,DATETIME15.);
run;
/*** ANY OTHER PROCS/DATA STEPS ***/
/*just remember to use &inLibref..&inMember. to refer to the current dataset*/
/*increment the iterator of the loop*/
%let iter=%eval(&iter.+1);
%end;
%mend;
/*call the macro*/
%loopOverDatasets()

Answer 1

Your updated information shows that you have observations in your input dataset Testwyf.Varlst with empty values of LIBNAME and MEMBER. Also having a period in the value of MEMBER is probably indication that it is either a numeric variable (or does not even exist in that dataset) or was generated from a numeric variable that had a missing value. So fix your input dataset.
Sometimes the macro processor interferes with SAS's ability to parse your code into tokens for evaluation and a single token that it being built with macro code is seen as two tokens instead of one. One simple solution is to build the token into another macro variable and then use that macro variable to generate the code.
In your case make macro variables to hold the full dataset names and then use those to generate the SAS code.
%let indsn = &inLibref..&inMember.;
%let outdsn = &outLibref..&inMember.;
data &outdsn.(drop=TradingTime);
set &indsn.(keep=Symbol ShortName TradingTime LastPrice OpenPrice);
Also protect yourself from non-standard member names.
call symputx("inMember",nliteral(memname));

Answer 2

I think Tom's generally right for finding the problem with this macro, so I'll suggest a totally different approach. %do loops are hard to troubleshoot, because the macro language isn't as good at logging errors.
Instead, my preferred approach is to do this as separate units.
Write a macro that does what you want done, once.
Write code that calls that macro once for each row in your dataset.
(1) is easy to do, hopefully. It's just the last part of your code.
(2) has a lot of different approaches, all of which are fine, depending on some details. If you're doing a reasonably small number of these, then the best approach in my opinion is proc sql select into, with the caveat that it has two majors issues: if there is a call execute up the line of it, you might not have the results you expect; and there is a 64000 character limit to the text of the select into, so if you have a lot of observations (or a smaller lot of very long calls) it can run into trouble. But if you're running this for a few hundred observations, you're probably cool doing it this way.
Here's one example of how to do this. Feel free to read my paper Writing Code With Your Data for a more detailed take on this.
*First, set up example dataset;
data change;
length var $32 expr $1024;
dataset='sashelp.class';
outset='class';
var='bmi';
expr='703*weight/(height**2)';
output;
dataset='sashelp.cars';
outset='cars';
var='mpg_avg';
expr='mean(mpg_city,mpg_highway)';
output;
run;
*Here, define the macro that will be run on each row of the dataset;
%macro change_ds(dataset=, outset=, var=, expr=);
data &outset;
set &dataset;
&var. = &expr. ;
run;
%mend change_ds;
*Now, use PROC SQL to select the macro calls into a macro variable;
*I leave off NOPRINT because I like to see the list in the results, but you can add it for production if you want;
proc sql;
select cats('%change_ds(dataset=',dataset,',outset=',outset,',var=',var,',expr=%nrstr(',expr,'))')
into :runlist separated by ' '
from change
where not missing(dataset) and not missing(outset) and not missing(var) and not missing(expr);
quit;
*Now, run it. Add the symbolgen/mprint options if it is helpful for debugging;
options symbolgen mprint;
&runlist.;
*Note, the semicolon above is not needed - I always include it to fix the syntax highlighting, but make sure you know it is not useful;