Padding middle of a string - xslt

Question

I have this requirement to pad strings so that they become 10 characters long.
Example strings :
AB..12
ABC...123
I need to add dots in the middle of the string (where dots are already present; at least one dot will always be present in the input string) in order to get the total length to 10 characters long:
AB......12
ABC....123
What would be a good way to accomplish this?
I have come up with this idea, which works, but is really not "nice".
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:xs="http://www.w3.org/2001/XMLSchema"
version="3.0">
<xsl:output method="xml" indent="yes"/>
<xsl:template match="/">
<xsl:variable name="test1" select="'AB..12'"/>
<xsl:variable name="dots" select="if(string-length($test1)=9) then '..'
else if(string-length($test1)=8) then '...'
else if(string-length($test1)=7) then '....'
else if(string-length($test1)=6) then '.....'
else ''"/>
<Result>
<Test1><xsl:value-of select="concat(substring-before($test1,'.'),$dots,substring-after($test1,'.'))"/></Test1>
</Result>
</xsl:template>
</xsl:stylesheet>

Answer 1

If you use a regular expression you can match the dots and compute the length; the following isn't really very compact but should do the job:
<xsl:param name="separator" as="xs:string" select="'.'"/>
<xsl:param name="pattern" as="xs:string" expand-text="no">^([^.]+)(\.+)([^.]+)$</xsl:param>
<xsl:template match="item">
<xsl:copy>
<xsl:analyze-string select="." regex="{$pattern}">
<xsl:matching-substring>
<xsl:value-of
select="regex-group(1),
(1 to 10 - string-length(regex-group(1)) - string-length(regex-group(3))) ! $separator,
regex-group(3)" separator=""/>
</xsl:matching-substring>
</xsl:analyze-string>
</xsl:copy>
</xsl:template>
I have assumed you have the string in an element to match on e.g. item in above sample, but you could of course stuff the xsl:analyze-string into a function instead and call it with any string you have.

Answer 2

Not a pure XSLT 3.0 solution but with the replace-with() function available as a Saxon extension, it's
replace-with($input, '\.+',
function($s){string-join((1 to 10-string-length($input))!'.')})

Answer 3

Thanks for both of your answers. Here's a simple answer I came up with based on your answers.
<xsl:variable name="output" select="concat(substring-before($input,'.'),string-join((1 to 10-string-length($input)+1)!'.'),substring-after($input,'.'))"/>
So basically take what's before the first dot, add the number of missing dots+1 and then add what's after the first dot.