Matching dates with weekdays, PowerBI - powerbi

Question

I have 2 tables, AvailabilitiesDB and AvailabilityTemplateDB.
The AvailabilitiesDB table looks like like
IsAvailable StartTime FinishTime Employee_ID Week Day Of the Week
1 25-09-2020 16:00:00 25-09-2020 19:00:00 101 39 5
0 27-08-2020 14:00:00 27-08-2020 17:00:00 13 35 4
1 25-11-2020 09:00:00 25-11-2020 18:00:00 66 48 3
The AvailabilityTemplateDB table looks like this:
Day Of The Week StartTime FinishTime Employee_ID
3 18:00:00 21:00:00 101
2 11:00:00 17:00:00 13
6 06:00:00 20:00:00 66
Here is the issue:
I want to calculate the availability of the employees, meaning their minutes available (so from StartTime to FinishTime).
However, the thing is: The employees all have a template (AvailabilityTemplateDB) which is their go-to work schedule, so if there is not any observations in AvailabilitiesDB, it means that they use their template. But if there is an observation for a specific employee in the AvailabilitiesDB, it means that the template has been overwritten for the specific day. The templates are recurrent every week, which is why they don't have specific dates, and just "Day of the Week".
So I want to calculate something along the lines of: calculate DatesBetween (Minutes), where employee id = employee id, and if there is a data in the availabilitiesDB it must use this number, so for the first observation it would be 180 minutes, but if there is not a date in there, it must take the time from the template table. I find this hard because all I have is "Day of the week" in the template table, and I don't know how i would "convert" it to dates.
This was what I have tried (Not near end result) and obviously it's not supposed to count rows, I was just trying in order to come closer to an answer. Date refers to my date table, which holds unique dates for all of the dates from the AvailabiltiesDB table.
Try =
VAR dates =
DATESBETWEEN (
'Date'[Date].[Date],
MIN ( 'Date'[Date].[Date] ),
MAX ( 'Date'[Date].[Date] )
)
VAR Employee_ID = AvailabilitiesDB[Employee_ID]
VAR Weekdays = AvailabilitiesDB[Day Of the Week]
VAR weekdaysAndDateMatch =
VAR COUNTZ =
CALCULATE (
COUNTROWS ( AvailabilitiesDB ),
FILTER (
AvailabilityTemplateDB,
Weekdays = AvailabilityTemplateDB[Day of the week]
&& Employee_ID = AvailabilityTemplateDB[Employee_ID]))
RETURN IF ( COUNTZ = 0, "Yes", "No" )
My desired outcome would be a column in the AvailabilitiesDB table that summed the availability in minutes per week, for every employee_ID.
I hope you can help me further, thank you in advance.

Answer 1

Events with a duration are simplified by implementing a snapshot table.
Another good practice when dealing with time is to split the date part and the time part in two different columns
So I created a small model with dimension Date, Employees and Time
For this example we just need the months from August to November. To match the Day of the week with the sample data I had to subtract 1.
Date =
ADDCOLUMNS (
CALENDAR ( "2020-08-01", "2020-11-30" ),
"WeekDay", WEEKDAY ( [Date] ) - 1
)
The Employees dimension is
Employees =
ADDCOLUMNS (
DISTINCT ( AvailabilitiesTemplateDB[Employee_ID] ),
"Name", FORMAT ( [Employee_ID], "000" )
)
For the time dimension I created a measure as a parameter with the time granularity to be used also for the snapshot table. This can be changed to adapt the model to the requirements.
To keep a low number of lines for this example I used a 1 hour interval
TimeInterval = VALUE( "01:00:00" )
So the Time table becomes
Time =
SELECTCOLUMNS (
GENERATESERIES ( VALUE ( "00:00:00" ), VALUE ( "23:59:59" ), [TimeInterval] ),
"Time", [Value]
)
The snapshot table is a table containing a row per each time interval for which an employee is available. To build this table we can use the set functions UNION and EXCEPT. The snapshot table has just three columns: the Employee_ID, the Date and the Time
This code matches the Date with the weekday using the Date table we build before
AvailabilitiesSnapshot =
VAR TimeGranularity = [TimeInterval]
VAR AvailableFromTemplateDB =
SELECTCOLUMNS(
GENERATE(
AvailabilitiesTemplateDB,
VAR DayOfWeek = AvailabilitiesTemplateDB[Day Of The Week]
VAR TimesTable =
SELECTCOLUMNS(
GENERATESERIES(
AvailabilitiesTemplateDB[StartTime],
AvailabilitiesTemplateDB[FinishTime] - TimeGranularity,
TimeGranularity
),
"Time", [Value]
)
RETURN
GENERATE(
FILTER( ALLNOBLANKROW( 'Date' ), 'Date'[WeekDay] = DayOfWeek ),
TimesTable
)
),
"Employee_ID", [Employee_ID],
"Date", [Date],
"Time", [Time]
)
VAR AvailableFromDB =
SELECTCOLUMNS(
GENERATE(
CALCULATETABLE( AvailabilitiesDB, AvailabilitiesDB[IsAvailable] = 1 ),
VAR TimesTable =
SELECTCOLUMNS(
GENERATESERIES(
AvailabilitiesDB[StartTimeOnly],
AvailabilitiesDB[FinishTimeOnly] - TimeGranularity,
TimeGranularity
),
"Time", [Value]
)
RETURN
TimesTable
),
"Employee_ID", [Employee_ID],
"Date", [Date],
"Time", [Time]
)
VAR UnavailableFromDB =
SELECTCOLUMNS(
GENERATE(
CALCULATETABLE( AvailabilitiesDB, AvailabilitiesDB[IsAvailable] = 0 ),
VAR TimesTable =
SELECTCOLUMNS(
GENERATESERIES(
AvailabilitiesDB[StartTimeOnly],
AvailabilitiesDB[FinishTimeOnly] - TimeGranularity,
TimeGranularity
),
"Time", [Value]
)
RETURN
TimesTable
),
"Employee_ID", [Employee_ID],
"Date", [Date],
"Time", [Time]
)
RETURN
EXCEPT(
DISTINCT( UNION( AvailableFromTemplateDB, AvailableFromDB ) ),
UnavailableFromDB
)
In this code first we add all available intervals, then we remove the intervals that are marked as not available, those with AvailabilitiesDB[IsAvailable] = 0
Then we create the relationships between this new snapshot table and the dimensions, to get the model
with this model, writing a measure to compute the available minutes is straigthforward
AvailableTime = COUNTROWS( AvailabilitiesSnapshot ) * [TimeInterval] * 24 * 60
The TimeInterval parameter can be changed to rise the detail level. Of course this will increase the number of rows of the snapshot table and also depends on the size of the input tables.