Calculating number of business days between 2 dates in SAS, - sas

Question

Member StartDate EndDate
1 27-Jul-17 27-Oct-17
2 27-Aug-19 11-Sep-19
3 28-Mar-17 31-Jul-17
4 17-Jun-19 13-Aug-19
5 21-Mar-17 16-May-17
6 17-Mar-17 05-Jul-17
7 20-Jan-16 11-Apr-16
8 27-Apr-15 09-Jun-15
9 13-Feb-19 19-Mar-19
10 27-May-15 30-Sep-15
11 16-Dec-16 30-Mar-17
12 17-Nov-16 02-Feb-17
data mydata;
set mdata;
weekdays=intck("weekdays",startdate,enddate);
run;
Holiday data is here:
holiday_date description
01/01/2003 New Years Day
17/02/2003 Family Day
18/04/2003 Good Friday
21/04/2003 Easter Monday
19/05/2003 Victoria Day
01/07/2003 Canada Day
04/08/2003 Civic Holiday
01/09/2003 Labour Day
13/10/2003 Thanksgiving Day
11/11/2003 Remembrance Day
25/12/2003 Christmas Day (*)
26/12/2003 Boxing Day (*)
01/01/2004 New Years Day
16/02/2004 Family Day
09/04/2004 Good Friday
12/04/2004 Easter Monday
24/05/2004 Victoria Day
01/07/2004 Canada Day
02/08/2004 Civic Holiday
I want to calculate number of week days excluding holidays. I have a table with the holidays dates. How do I apply it for each record to calculate business days?

Answer 1

This example is copied from SAS documentation.
Example 3: Using Custom Intervals with the INTCK Function
options intervalds=(BankingDays=BankDayDS);
data BankDayDS(keep=begin);
start = '15DEC1998'd;
stop = '15JAN2002'd;
nwkdays = intck('weekday',start,stop);
do i = 0 to nwkdays;
begin = intnx('weekday',start,i);
year = year(begin);
if begin ne holiday('NEWYEAR',year) and
begin ne holiday('MLK',year) and
begin ne holiday('USPRESIDENTS',year) and
begin ne holiday('MEMORIAL',year) and
begin ne holiday('USINDEPENDENCE',year) and
begin ne holiday('LABOR',year) and
begin ne holiday('COLUMBUS',year) and
begin ne holiday('VETERANS',year) and
begin ne holiday('THANKSGIVING',year) and
begin ne holiday('CHRISTMAS',year) then
output;
end;
format begin date9.;
run;
data CountDays;
start = '01JAN1999'd;
stop = '31DEC2001'd;
ActualDays = intck('DAYS',start,stop);
Weekdays = intck('WEEKDAYS',start,stop);
BankDays = intck('BankingDays',start,stop);
format start stop date9.;
run;
title 'Methods of Counting Days';
proc print data=CountDays;
run;
In response to the comment.
data mydata;
input Member (StartDate EndDate)(:date.);
format startdate enddate date11.;
cards;
1 27-Jul-17 27-Oct-17
2 27-Aug-19 11-Sep-19
3 28-Mar-17 31-Jul-17
4 17-Jun-19 13-Aug-19
5 21-Mar-17 16-May-17
6 17-Mar-17 05-Jul-17
7 20-Jan-16 11-Apr-16
8 27-Apr-15 09-Jun-15
9 13-Feb-19 19-Mar-19
10 27-May-15 30-Sep-15
11 16-Dec-16 30-Mar-17
12 17-Nov-16 02-Feb-17
;;;;
run;
proc print;
run;
proc summary data=mydata nway missing;
output out=range(drop=_:) min(startdate)=start max(enddate)=stop;
run;
proc print;
run;
options intervalds=(BankingDays=BankDayDS);
data BankDayDS(keep=begin);
set range;
nwkdays = intck('weekday',start,stop);
do i = 0 to nwkdays;
begin = intnx('weekday',start,i);
year = year(begin);
if begin ne holiday('NEWYEAR',year) and
begin ne holiday('MLK',year) and
begin ne holiday('USPRESIDENTS',year) and
begin ne holiday('MEMORIAL',year) and
begin ne holiday('USINDEPENDENCE',year) and
begin ne holiday('LABOR',year) and
begin ne holiday('COLUMBUS',year) and
begin ne holiday('VETERANS',year) and
begin ne holiday('THANKSGIVING',year) and
begin ne holiday('CHRISTMAS',year) then
output;
end;
format begin date9.;
run;
data mydata;
set mydata;
ActualDays = intck('DAYS',startdate,enddate);
weekdays = intck("weekdays",startdate,enddate);
BankDays = intck('BankingDays',startdate,enddate);
run;
title 'Methods of Counting Days';
proc print data=mydata;
run;