SAS PROC TRANPOSE ("Wide to Long") - sas

Question

I have this original dataset #1 ("HAVE"), which contains 2 teams playing for each record:
DATA HAVE;
INPUT DATE :yymmdd10. Home_Team $ Away_Team $ Home_Rate Away_Rate ;
format DATE yymmddd10.;
datalines;
2020-07-26 Arsenal Watford 2.0 3.6
2020-07-26 Burnley Brighton 2.6 2.8
;
RUN;
What I want is to use PROC TRANSPOSE so that each record only contains 1 team, i.e. ("WANT"):
DATA WANT;
INPUT DATE :yymmdd10. TEAM $ TYPE $ Rate;
format DATE yymmddd10.;
datalines;
2020-07-26 Arsenal HOME 2.0
2020-07-26 Watford AWAY 3.6
2020-07-26 Burnley HOME 2.6
2020-07-26 Brighton AWAY 2.8
;
RUN;
Currently I can use 2 data steps then UNION to get the results - just figure it can be more clean with the PROC TRANPOSE - trying the different combinations of BY/ID/VAR combinations but still cannot seem to get the right results.

Answer 1

So, the general approach here is the double transpose. First transpose so that your variables are rows, and then grab the TYPE from that (and the desired variable name). Then transpose again. Here's an example:
DATA HAVE;
INPUT DATE :yymmdd10. Home_Team $ Away_Team $ Home_Rate Away_Rate ;
format DATE yymmddd10.;
datalines;
2020-07-26 Arsenal Watford 2.0 3.6
2020-07-26 Burnley Brighton 2.6 2.8
;
RUN;
proc transpose data=have out=have_t;
by date;
var home: away:;
run;
data pre_t;
set have_t;
by date;
type = scan(_NAME_,1,'_');
varn = scan(_NAME_,2,'_');
run;
proc transpose data=pre_t out=want;
by date type notsorted;
id varn;
var col1 col2;
run;
Now, there's one downside to this - the values in Rate will now be character. You can avoid that if you want by doing the first transpose differently (either using a data step, or using two proc transposes one for the numerics and one for the characters), or you can just re-convert them in a later datastep.