Batch files: using the result of compare in variable? - if-statement

Question

Here is the example:
set /a "number1=1"
set /a "number2=10"
if %number1% LSS %number2% (set /a "number1=%number1%+1")
echo result=%number1%
This code displays:
result=2
Is it possible in batch file to change the if statement to something like:
set /a "number1=%number1%+(%number1% LSS %number2%)"
?
The changed code at this moment displays:
Unbalanced parenthesis.
result=1

Answer 1

The set /A command does not feature comparison operators.
However, there is a way to compare two numbers and to get a value of -1 if the first number is less than the second one. For this, we need to know that the logical right-shift operator >> actually performs an arithmetic shift, meaning that the value of the most significant bit, which represents the sign, is shifted in at the left, hence the current sign of the number is maintained.
So for example:
the number +10 (binary representation 00000000 00000000 00000000 00001010) shifted to the right by one bit becomes +5 (binary representation 00000000 00000000 00000000 00000101);
the number -10 (binary representation 11111111 11111111 11111111 11110110) shifted to the right by one bit becomes -5 (binary representation 11111111 11111111 11111111 11111011);
When we shift to the right by 31 (or more) bit positions, the result is 32 times the sign bit (as we have 32-bit signed integers), which results in a value of -1 for negative input values and 0 for others.
When we now apply this technique, it leads us to the following code:
set /A "number1=%number1%-((%number1%-%number2%)>>31)"
You may omit the surrounding %-signs since set /A interprets any character strings that do not represent numbers or operators as variable names anyway:
set /A "number1=number1-((number1-number2)>>31)"
This can be further simplified using the appropriate assignment operator:
set /A "number1-=(number1-number2)>>31"

Answer 2

So your looking for something like a function or macro you can pass the values to for assessment?
The below is a macro demonstrating the concept. It is not a complete solution, as strings should be padded so they of equal length prior to assesment
#Echo Off
Set "Compare=Set "$RV="&For %%n in (1 2)Do if %%n==2 (For /F "Tokens=1,2 Delims={}" %%G in ("!Strings!")Do ((If "%%~G" LSS "%%~H" (Set "$RV=LSS") Else If "%%~G" EQU "%%~H" (Set "$RV=EQU") Else If "%%~G" GTR "%%~H" (Set "$RV=GTR"))&Echo/%%~G !$RV! %%~H))Else Set Strings="
Setlocal EnableDelayedExpansion
rem // example usage
%Compare:$RV=Ex[1]%{one}{oneb}
%Compare:$RV=Ex[2]%{one}{one}
%Compare:$RV=Ex[3]%{oneb}{one}
%Compare:$RV=Ex[4]%{13}{02}
%Compare:$RV=Ex[5]%{02}{13}
Echo/rem // Integers need to be 0 prefixed and strings should be padded to equal length or will return false:
%Compare:$RV=Ex[6]%{2}{13}
%Compare:$RV=Ex[7]%{two}{oneplus}
Set Ex[
Below is the fully realised compare macro that Pads strings to prevent false results when string lengths differ. The macro is defined using the \n newline syntax for the sake of readablitiy, however the compound version is also included.
#Echo Off & Setlocal DISABLEdelayedexpansion
rem // Pads string with 125 characters to prevent false results when string lengths differ. If comparing strings exceeding 125 characters in length,
rem // increase length of the padding and adjust s1 and s2 Substring modification length to match the number of padding characters.
Set "PAD=00000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000"
(Set \n=^^^
%= Newline Variable. Do not Modify. =%
)
Set Compare=Set "$RV=" ^& For %%n in (1 2)Do if %%n==2 (%\n%
For /F "Tokens=1,2 Delims={}" %%G in ("!Strings!")Do (%\n%
Set "s1=!PAD!%%~G" ^& Set "s1=!s1:~-125!" ^& Set "s2=!PAD!%%~H" ^& Set "s2=!s2:~-125!"%\n%
If "!s1!" LSS "!s2!" (Set "$RV=LSS")%\n%
If "!s1!" EQU "!s2!" (Set "$RV=EQU")%\n%
If "!s1!" GTR "!s2!" (Set "$RV=GTR")%\n%
Echo/%%~G !$RV! %%~H%\n%
)%\n%
)Else Set Strings=
Setlocal ENABLEdelayedexpansion
rem // example usages
For %%A in (one two three)Do for %%B in (three two one)Do %Compare:$RV=Ex[0]%{%%A}{%%B}
%Compare:$RV=Ex[1]%{one}{oneb}
%Compare:$RV=Ex[2]%{one}{one}
%Compare:$RV=Ex[3]%{oneb}{one}
%Compare:$RV=Ex[4]%{13}{2}
%Compare:$RV=Ex[5]%{2}{13}
Set Ex[
Endlocal & Endlocal & Goto :Eof
rem // compound version of Compare Macro:
Set "Compare=Set "$RV="&For %%n in (1 2)Do if %%n==2 (For /F "Tokens=1,2 Delims={}" %%G in ("!Strings!")Do (Set "s1=!PAD!%%~G"&Set "s2=!PAD!%%~H"&Set "s1=!s1:~-125!"&Set "s2=!s2:~-125!"&(If "!s1!" LSS "!s2!" (Set "$RV=LSS") Else If "!s1!" EQU "!s2!" (Set "$RV=EQU") Else If "!s1!" GTR "!s2!" (Set "$RV=GTR"))&Echo/%%~G !$RV! %%~H&Set "s1="&Set "s2=")) Else Set Strings="
Compare macro is case sensitive. Change the If conditions within the macro to include the /I switch if you require case to be ignored
To use the macro in the Desired context:
(%compare%{String 1}{String 2}) > Nul & If "!$RV!"=="LSS" (Echo/true)& Rem // replace Echo command within Parantheses with desired command
with Strings 1 and 2 being stand ins for whatever variables or For loop tokens you're comparing.