Get First and Last Sunday in Month with XSLT - xslt

Question

I am trying to convert a date from XML that comes in UTC format into multiple time zones. I will be able to use the lines below to get that, but I am having trouble calculating the differences for summertime/winter times. Is there any way I can get the first Sunday/last Sunday from a month?
xs:dateTime(/root/field/#myField)+xs:dayTimeDuration('PT1H')
xs:dateTime(/root/field/#myField)+xs:dayTimeDuration('PT2H')
where XML will be:
<root>
<field myField="2002-12-24T12:00:12Z"/>
</root>
Thanks!

Answer 1

Here's a way to calculate the first Sunday in the month of a given date:
XML
<input>
<event date="2020-01-20"/>
<event date="2020-02-03"/>
<event date="2020-03-17"/>
<event date="2020-04-29"/>
<event date="2020-05-09"/>
<event date="2020-06-11"/>
<event date="2020-07-06"/>
<event date="2020-08-15"/>
<event date="2020-09-28"/>
<event date="2020-10-01"/>
<event date="2020-11-30"/>
<event date="2020-12-17"/>
</input>
XSLT 2.0
<xsl:stylesheet version="2.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:xs="http://www.w3.org/2001/XMLSchema"
exclude-result-prefixes="xs">
<xsl:output method="xml" version="1.0" encoding="utf-8" indent="yes"/>
<xsl:template match="/input">
<results>
<xsl:for-each select="event">
<xsl:variable name="date" select="xs:date(#date)"/>
<xsl:variable name="day1" select="$date - (day-from-date($date) - 1) * xs:dayTimeDuration('P1D')"/>
<xsl:variable name="weekday" select="xs:integer(format-date($day1, '[F1]'))"/>
<first-sunday>
<xsl:value-of select="$day1 + (7 - $weekday) * xs:dayTimeDuration('P1D')"/>
</first-sunday>
</xsl:for-each>
</results>
</xsl:template>
</xsl:stylesheet>
Result
<?xml version="1.0" encoding="utf-8"?>
<results>
<first-sunday>2020-01-05</first-sunday>
<first-sunday>2020-02-02</first-sunday>
<first-sunday>2020-03-01</first-sunday>
<first-sunday>2020-04-05</first-sunday>
<first-sunday>2020-05-03</first-sunday>
<first-sunday>2020-06-07</first-sunday>
<first-sunday>2020-07-05</first-sunday>
<first-sunday>2020-08-02</first-sunday>
<first-sunday>2020-09-06</first-sunday>
<first-sunday>2020-10-04</first-sunday>
<first-sunday>2020-11-01</first-sunday>
<first-sunday>2020-12-06</first-sunday>
</results>