Grouping XML Values Based On XML Attributes (XSLT) - xslt

Question

Below are three rows of data (tab separated) that are to be transformed into an XML using XSLT.
Column_1 Column_2 Column_3 Column_4
A B C D
A B A F
C B D C
The Expected output is as below
<firstTag Column_1 ='A' Column_2='B'>
<secondTag Column_3='C' Column_4='D'/>
<secondTag Column_3='A' Column_4='F'/>
</firstTag>
<firstTag Column_1 ='C' Column_2='B'>
<secondTag Column_3='D' Column_4='C'/>
</firstTag>
How would one be able to group these rows based on one or more attribute values (Column_1 and Column_2) using XSLT

Answer 1

You can use unparsed-text or (in XSLT 3 supported since 2017 by Saxon 9.8 and later) unparsed-text-lines to process non-XML text files like the one you seem to have, then you have the tokenize function plus the xsl:analyze-string element or in XSLT 3 the analyze-string function to process and structure your tab delimited data into something you can feed to xsl:for-each-group, i.e. some XML or some mixture of arrays and sequences of string in XSLT 3.
Grouping in XSLT 2 and 3 is covered in https://stackoverflow.com/tags/xslt-grouping/info.
Here is an example using XSLT 3 and for-each-group over a grouping population that is a sequence of arrays of strings:
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:xs="http://www.w3.org/2001/XMLSchema"
xmlns:math="http://www.w3.org/2005/xpath-functions/math"
xmlns:map="http://www.w3.org/2005/xpath-functions/map"
xmlns:array="http://www.w3.org/2005/xpath-functions/array"
exclude-result-prefixes="#all"
version="3.0">
<xsl:param name="text" as="xs:string">Column_1 Column_2 Column_3 Column_4
A B C D
A B A F
C B D C</xsl:param>
<xsl:param name="el1" as="xs:string">firstElement</xsl:param>
<xsl:param name="el2" as="xs:string">secondElement</xsl:param>
<xsl:variable name="rows" as="array(xs:string)*" select="($text => tokenize('\r?\n')) ! array { tokenize(., '\s+') }"/>
<xsl:variable name="data-rows" select="$rows => tail()"/>
<xsl:variable name="column-names" select="$rows[1]?*"/>
<xsl:output method="xml" indent="yes"/>
<xsl:template match="/" name="xsl:initial-template">
<result>
<xsl:for-each-group select="$data-rows" composite="yes" group-by="?1, ?2">
<xsl:element name="{$el1}">
<xsl:attribute name="{$column-names[1]}" select="current-grouping-key()[1]"/>
<xsl:attribute name="{$column-names[2]}" select="current-grouping-key()[2]"/>
<xsl:apply-templates select="current-group()"/>
</xsl:element>
</xsl:for-each-group>
</result>
</xsl:template>
<xsl:template match=".[. instance of array(xs:string)]">
<xsl:element name="{$el2}">
<xsl:for-each select="?(3 to array:size(current()))">
<xsl:attribute name="{subsequence($column-names, position() + 2, 1)}" select="."/>
</xsl:for-each>
</xsl:element>
</xsl:template>
</xsl:stylesheet>
When I copied the input sample from your question it didn't seem to contain tab characters so I tokenized on whitespace instead.