Fortran 90: Repeated elements of a string - fortran

Question

I want to write a program that tells me how many times appears each letter of a character of some dimension n. For example:
Character(length=4) :: char="hello"
The program must give me:
'H appeared: ' 1 'time'
'E appeared: ' 1 'time'
'L appeared: ' 2 'times'
'O appeared: ' 1 'time'
Here's picture of what I've done, But of course it has some errors and idk how to fix it. For instance, i want it to print each letter only once, but because the write(,) is inside the first 'do i=...' each n-repeated letter is printed n times.
enter image description here

Answer 1

First of all after looking at you code, I would suggest using IMPLICIT none. Also you have a few redundant variables which I have attempted to remove.
Also, in order to ensure each character is processed only once (which is your question), you need to have an additional do loop to check whether the next character string has already been processed. I have include a possible answer below, though have turned off the IMPLICIT feature but tried to keep in line with your coding style:
PROGRAM MAIN
IMPLICIT NONE
INTEGER :: N,I,J
CHARACTER*8 CHAAR
LOGICAL PROCCHAR
CHAAR = "homework"
DO I=1,8
N=1
C **** FIRST CHECK THIS CHARACTER HAS NOT BEEN PROCESSED ALREADY
PROCCHAR = .TRUE.
DO J=1,i-1
IF(CHAAR(I:I) == CHAAR(J:J)) THEN
PROCCHAR = .FALSE.
ENDIF
ENDDO
C **** LOOK THROUGH REST OF CHARACTER STRING. BUT ONLY IF THIS
C CHARACTER HAS NOT BEEN PROCESSED SO FAR
DO J=i+1,8
IF(CHAAR(I:I) == CHAAR(J:J).AND.PROCCHAR) THEN
C AUX = CHAAR(J:J)
N = N + 1
ENDIF
ENDDO
IF(PROCCHAR) WRITE(*,*) 'CHARAACTER ',CHAAR(I:I),' OCCURS ',N
ENDDO
END

Answer 2

SCAN, INDEX, VERIFY are the most notable Fortran intrinsic functions dealing with character search in strings. For example, this is a case-insensitive working implementation:
program test_hello
implicit none
character(len=*), parameter :: upperAlphabet = "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
character(len=*), parameter :: lowerAlphabet = "abcdefghijklmnopqrstuvwxyz"
call printLettersInWord("hello")
call printLettersInWord("fortran")
contains
subroutine printLettersInWord(word)
character(len=*), intent(in) :: word
integer :: j,letterCount(0:len(upperAlphabet))
if (len_trim(word)<=0) return
print *, 'In word <',word,'>:'
letterCount = countLetters(word)
do j=1,len(upperAlphabet)
if (letterCount(j)<=0) cycle
print "(' letter ',a,' found ',i0,' times ')", upperAlphabet(j:j),letterCount(j)
end do
end subroutine printLettersInWord
pure function countLetters(word) result(letterCount)
character(len=*), intent(in) :: word
integer :: letterCount(0:len(upperAlphabet))
integer :: i,thisLetter
letterCount = 0
do i=1,len(word)
thisLetter = max(index(upperAlphabet,word(i:i)),index(lowerAlphabet,word(i:i)))
letterCount(thisLetter) = letterCount(thisLetter)+1
end do
end function countLetters
end program test_hello
That produces the following output:
In word <hello>:
letter E found 1 times
letter H found 1 times
letter L found 2 times
letter O found 1 times
In word <fortran>:
letter A found 1 times
letter F found 1 times
letter N found 1 times
letter O found 1 times
letter R found 2 times
letter T found 1 times