xsl:if evaluation with nmap output - xslt

Question

For reference I am using Nmap 7.8, and I am attempting to format the output using an xsl file. Within the xsl file I call a second rules.xml file to do comparisons and add supplemental information. This is the structure of rules.xml
<?xml version="1.0" encoding="UTF-8"?>
<root>
<Item id="1">
<info>Rule Information</info>
<port>123</port>
<port>321</port>
</Item>
</root>
When I attempt to print the output of an nmap port with <xsl:value-of select="#portid"/> it works, however if I do an if, or choose/when operation it fails. When I do a static comparison <xsl:if test="port = 321"> it works with either port value.
<xsl:for-each select="ports/port">
<xsl:choose>
<xsl:when test="state/#state = 'open'">
<xsl:variable name="rules" select="document('rules.xml')"/>
<xsl:for-each select="$rules/root/Item">
<xsl:if test="port = #portid">
<xsl:value-of select="info"/>
</xsl:if>
</xsl:for-each>
</xsl:when>
</xsl:choose>
</xsl:for-each>
The desired behavior is to loop through all ports within the nmap output and add the additional info tags in an Item which contains a matching port tag. The mapping is 1 Item to Many ports, so I would like to avoid indexing rules.xml with ports at the top level to prevent duplicate .

Answer 1

When using expressions like port = #portId you need to think about what the context item is. There's no element that has both a child port and an attribute portId, so it looks like the two sides of this expression are expecting different context items, which of course can't happen.
Generally when you're doing joins between several documents (or within a single document) you need to bind variables to nodes so that you can make explicit selections rather than relying on implicit context.

Answer 2

I am guessing you want to do:
<xsl:for-each select="ports/port">
<xsl:choose>
<xsl:when test="state/#state = 'open'">
<xsl:variable name="portid" select="#portid"/>
<xsl:variable name="rules" select="document('rules.xml')"/>
<xsl:for-each select="$rules/root/Item">
<xsl:if test="port = $portid">
<xsl:value-of select="info"/>
</xsl:if>
</xsl:for-each>
</xsl:when>
</xsl:choose>
</xsl:for-each>
or perhaps more succinctly:
<xsl:variable name="rules" select="document('rules.xml')"/>
<xsl:for-each select="ports/port[state/#state = 'open']">
<xsl:variable name="portid" select="#portid"/>
<xsl:for-each select="$rules/root/Item[port = $portid]">
<xsl:value-of select="info"/>
</xsl:for-each>
</xsl:for-each>
What you have now is looking for Item that has a child port whose value is equal to the value of the portid attribute of the parent Item.