Why am I failing to read and write to Amazon S3 from a Delphi VCL application? - amazon-web-services

Question

I have created a Delphi application from which I want to read and write from an Amazon S3 (simple storage service) bucket.
In the S3 Management Console I have created a new bucket and set Block all public access to On.
I then created a new user for IAM (Identify and Access Management) and granted this user AmazonS3FullAccess privileges (for now). In my application I added a TAmazonConnectionInfo component to my project, and set the AccountKey property to the secret access key, and the AccountName property to my account key ID of this IAM user.
In my code I am instantiating a TAmazonStorageService class, passing the TAmazonConnectionInfo object to it in the constructor. I am then invoking the UploadObject method to which I pass the bucket name, an object name, and a TArray that contains the object I want to store. The call to UploadObject returns False. I’ve tried several different byte arrays, including one based on the example shown in one of the YouTube videos that I’ve referenced at the bottom of this post, so I’m pretty sure that it’s not a problem with the object I am trying to store.
I tried setting Block all public access to Off, but that did not solve the problem. I don’t know how long it takes for those settings to take effect, but there was no difference in result after half of an hour.
Either I have not sufficiently configured my TAmazonConnectionInfo object, or there are one or more objects that I need to add to the project, or some configuration that I need to perform on the bucket.
One concern I have is that my S3 bucket is located in US East (Ohio) region. The Region property of the TAmazonConnectionInfo component is set to amzrUSEast1, but I am not sure that that is correct. I tried setting Region to amzrNotSpecified, but that did not solve the problem.
Also, I tried setting StorageEndPoint to s3.us-east-2.amazonaws.com (http) and s3-accesspoint.us-east-2.amazonaws.com (https), based on Paweł’s comments.
I’ve exhausted my options. If you’re having success working with your S3 buckets from Delphi I would be grateful if you could help point me in the right direction.
I am using Delphi Rio 10.3.3 on Windows 10 64-bit
References:
https://www.youtube.com/watch?v=RUT9clew4PM&t=396s
https://www.youtube.com/watch?v=rtZkVAOvavU&t=1582s
https://www.youtube.com/watch?v=8VjTEtK_VaM&list=PLwUPJvR9mZHg3YgQKG8QCJAqdNxZyDVfg&index=50&t=0s

Answer 1

The code below works. Plug in your values for AccountName, AccountKey and BucketName and try it. If it fails, let us know what it returned for your response.
To test this, I created a new bucket with default settings: US East (Ohio) us-east-2 region and block all public access checked. I created a new user with programmatic access and assigned it the policy AmazonS3FullAccess.
During my initial test I got this 400 response which was resolved by setting the StorageEndpoint:
400: Bad Request - The authorization header is malformed; the region
'us-east-1' is wrong; expecting 'us-east-2'
(AuthorizationHeaderMalformed)
If you get a 403 response like below, check to make sure the user policy (or however you configured your permissions) is set correctly, and that your AccountName and AccountKey are correct.
403: Forbidden
program AmazonS3test;
{$APPTYPE CONSOLE}
{$R *.res}
uses
System.SysUtils, Data.Cloud.CloudAPI, Data.Cloud.AmazonAPI, System.Classes;
const
AccountName = ''; // IAM user Access key ID
AccountKey = ''; // IAM user Secret access key
BucketName = ''; // S3 bucket name
StorageEndpoint = 's3-us-east-2.amazonaws.com'; // s3-<bucket region>.amazonaws.com
ObjectName = 'TestFile.txt';
MyString = 'Testing 1 2 3';
var
ResponseInfo: TCloudResponseInfo;
ConnectionInfo: TAmazonConnectionInfo;
StorageService: TAmazonStorageService;
StringStream: TStringStream;
begin
ReportMemoryLeaksOnShutdown := True;
ConnectionInfo := TAmazonConnectionInfo.Create(nil);
StorageService := TAmazonStorageService.Create(ConnectionInfo);
ResponseInfo := TCloudResponseInfo.Create;
StringStream := TStringStream.Create(MyString);
try
try
ConnectionInfo.AccountName := AccountName;
ConnectionInfo.AccountKey := AccountKey;
ConnectionInfo.StorageEndpoint := StorageEndpoint;
StorageService.UploadObject(BucketName, ObjectName,
StringStream.Bytes, True, nil, nil, amzbaPrivate, ResponseInfo);
WriteLn('StatusCode: ' + IntToStr(ResponseInfo.StatusCode));
WriteLn('Status : ' + ResponseInfo.StatusMessage);
except
on E: Exception do
WriteLn(E.ClassName, ': ', E.Message);
end;
finally
StringStream.Free;
ResponseInfo.Free;
StorageService.Free;
ConnectionInfo.Free;
end;
end.