How to RegEx a string into a list? - regex

Question

How can I RegEx this string into a list?
My String is like this:
google (2.0.3) - Python bindings to the Google search engine.
bits-google (1.12.17) - BITS Google
oauthkit-google (0.1.2) - OAuthKit for Google
google-reauth (0.1.0) - Google Reauth Library
google-common (0.0.1) - Google namespace package
google-colab (1.0.0) - Google Colaboratory tools
google-auth (1.11.2) - Google Authentication Library
INSTALLED: 1.7.0
LATEST: 1.11.2
google-endpoints (4.8.0) - Google Cloud Endpoints
google-oauth (1.0.1) - OAuth2 for Google APIs
google-gax (0.16.0) - Google API Extensions
google-finance (0.1.0) - Google Finance API ikmgitj oijhotrjtrhj
kjhghjihotrhjtri9h
I want to get the name, the version, the description, and eventually if its installed.
I know how to separate a string with only one space, but how do I do that when the string has multiple spaces which vary and also have a dash in it?
EDIT:
I integrated the code now like this (For the people who are interested. Credit):
Dim patt = "(.*?.)(\(\d+.\d+.\d+\)|\d+.\d+.\d+)(=?.*?-.)?(.*)"
Dim matches = Regex.Matches(sOutput, patt, RegexOptions.IgnoreCase)
Dim found_packages As New Dictionary(Of String, List(Of String))
For Each m As Match In matches
Dim key = m.Groups(1).Value.Trim({" "c, ":"c})
If key = "INSTALLED" Then
found_packages(found_packages.Last().Key).Add(m.Groups(2).Value.Trim({" "c, ":"c}))
Continue For
ElseIf key = "LATEST" Then
Continue For
End If
found_packages.Add(key, New List(Of String))
found_packages(key).Add(m.Groups(2).Value.Trim({" "c, ":"c}).Replace("(", "").Replace(")", ""))
If Not String.IsNullOrWhiteSpace(m.Groups(4).Value) Then
found_packages(key).Add(m.Groups(4).Value.Trim({" "c, ":"c}))
End If
Next
For Each package In found_packages
Dim item As New ListViewItem
item.Text = package.Key
item.SubItems.Add(package.Value(0))
item.SubItems.Add(package.Value(1))
If package.Value.Count > 2 Then
item.SubItems.Add(package.Value(2))
End If
lvPackages.Items.Add(item)
Next

Answer 1

You can use RegEx to parse this input and create a Dictionary(Of String, List(Of String)) where each key-value entry is a property (the name) with several values (the version and the description):
Dim patt = "(.*?.)(\(\d+.\d+.\d+\)|\d+.\d+.\d+)(=?.*?-.)?(.*)"
Dim matches = Regex.Matches(txtIn.Text, patt)
Dim dict As New Dictionary(Of String, List(Of String))
For Each m As Match In matches
Dim key = m.Groups(1).Value.Trim({" "c, ":"c})
dict.Add(key, New List(Of String))
dict(key).Add(m.Groups(2).Value.Trim({" "c, ":"c}))
If Not String.IsNullOrWhiteSpace(m.Groups(4).Value) Then
dict(key).Add(m.Groups(4).Value.Trim({" "c, ":"c}))
End If
Next
The dict contains the following:
google
(2.0.3)
Python bindings to the Google search engine.
bits-google
(1.12.17)
BITS Google
oauthkit-google
(0.1.2)
OAuthKit for Google
google-reauth
(0.1.0)
Google Reauth Library
google-common
(0.0.1)
Google namespace package
google-colab
(1.0.0)
Google Colaboratory tools
google-auth
(1.11.2)
Google Authentication Library
INSTALLED
1.7.0
LATEST
1.11.2
google-endpoints
(4.8.0)
Google Cloud Endpoints
google-oauth
(1.0.1)
OAuth2 for Google APIs
google-gax
(0.16.0)
Google API Extensions
google-finance
(0.1.0)
Google Finance API ikmgitj oijhotrjtrhj kjhghjihotrhjtri9h
You can get the values (version and description) of the google key (name) for example as follows:
Dim version = dict("google")(0)
Dim descrip = dict("google")(1)
Note that, both INSTALLED and LATEST keys have no description value, so the Dim descrip = dict("LATEST")(1) will throw an exception. So you have to check first. Now you have the dict dictionary where the dict.Keys are the name-s and the dict.Values are the version-s and description-s for each key.
If you just want to create a List(Of String):
Dim patt = "(.*?.)(\(\d+.\d+.\d+\)|\d+.\d+.\d+)(=?.*?-.)?(.*)"
Dim matches = Regex.Matches(txtIn.Text, patt)
Dim lst As New List(Of String)
For Each m As Match In matches
lst.Add(m.Groups(1).Value.Trim({" "c, ":"c}))
lst.Add(m.Groups(2).Value.Trim({" "c, ":"c}))
If Not String.IsNullOrWhiteSpace(m.Groups(4).Value) Then
lst.Add(m.Groups(4).Value.Trim({" "c, ":"c}))
End If
Next
Here's the regex101 test for the preceding RegEx pattern.
Edit: Suggested Improvements
According to your last edit which clarifies what you are trying to achieve, I'd like to suggest the following:
You can get rid of the Dictionary(Of String, List(Of String)) and work directly with the ListViewItemCollection of the ListView control. This way, just one ForEach loop will do the job.
Dim patt = "(.*?.)(\(\d+.\d+.\d+\)|\d+.\d+.\d+)(=?.*?-.)?(.*)"
Dim matches = Regex.Matches(sOutput.Text, patt)
lvPackages.BeginUpdate()
lvPackages.Items.Clear()
For Each m As Match In matches
Dim key = m.Groups(1).Value.Trim({" "c, ":"c})
If key.IndexOf("latest", StringComparison.InvariantCultureIgnoreCase) >= 0 Then
Continue For
End If
Dim lvi As ListViewItem
If key.IndexOf("installed", StringComparison.InvariantCultureIgnoreCase) >= 0 Then
lvi = lvPackages.Items.OfType(Of ListViewItem).LastOrDefault
'Just in case
If lvi IsNot Nothing Then
lvi.SubItems.Add(m.Groups(2).Value.Trim({" "c, ":"c}))
End If
Continue For
End If
lvi = New ListViewItem(key)
'Add the version..
lvi.SubItems.Add(Regex.Match(m.Groups(2).Value, "\d+.\d+.\d+").Value)
If Not String.IsNullOrWhiteSpace(m.Groups(4).Value) Then
'Add the description..
lvi.SubItems.Add(m.Groups(4).Value.Trim({" "c, ":"c}))
End If
lvPackages.Items.Add(lvi)
Next
'Optional: Auto size each column to fit the longest item.
lvPackages.Columns.Cast(Of ColumnHeader).
ToList().ForEach(Sub(x) x.Width = -1)
lvPackages.EndUpdate()
Check it out.

Answer 2

This is a job for regular expressions. You can parse the string using a variable number of whitespace characters. I'm not sure about vb, but in python I would do something like this (but iterating over each line by splitting based on the \r):