Counting Records the Pass Over Midnight - sas

Question

I have two datasets:
1) Let's call the fist data set - "Provider". It contains a year's list of providers (over 3900 shifts/records), the date which they worked a shift and the shift type. Note that there are shift types that span over midnight.
Date Provider Shift
1/8/2019 Bob ED A/B 11p-7a (ED A/B)
1/10/2019 Bob ED C/D 11p-7a (ED C/D)
1/16/2019 Bob ED C 3p-12a (ED C)
1/9/2019 Sue UMC 5p-2a (UMC)
1/11/2019 Bob ED C/D 11p-7a (ED C/D)
1/13/2019 Bob ED PH/night 10p-4a (ED PH/night)
2) I have another data set - "Patients". It contains the year's worth of FINs, date/time when they saw a provider, and the name of the provider they saw of all patients seen at our location.
FIN Date Provider Name
1 1/8/2019 23:40 Bob
2 1/9/2019 01:46 Timbo
3 1/9/2019 01:30 Bob
4 1/9/2019 05:06 Patty
5 1/9/2019 02:50 Bob
6 1/9/2019 17:23 Sue
7 1/9/2019 06:45 Mike
8 1/10/2019 01:35 Sue
I'm looking to create a new data set that contains the number of patients seen during a given shift.
So for example the data set would look like this:
Shift date Shift FIN Provider
1/8/2019 ED A/B 11p-7a (ED A/B) 1 Bob
1/8/2019 ED A/B 11p-7a (ED A/B) 3 Bob
1/8/2019 ED A/B 11p-7a (ED A/B) 5 Bob
1/9/2019 UMC 5p-2a (UMC) 6 Sue
1/9/2019 UMC 5p-2a (UMC) 8 Sue
I could very easily create this data set by merging the two data sets then matching based on date and provider name; however, as I mentioned before, some of the shifts span past midnight so I am unable to match by date.
There are roughly 20 different shift types I'm interested in gathering data for, of which 6 span over midnight. I would need to structure my data so that say if a provider worked the ED A/B 11p-7a (ED A/B) shift on 1/8/2019 then count any patient who he/she also saw before 7am on 1/9/2019? If possible, I would then need to create some sort of macro (I think).
Hope this makes sense - thanks for help!

Answer 1

You will need to process the Provider data to compute shift start and end datetimes. This will require locating the ##p-##a, and, presumably, also ##a-##a , ##a-##p and ##p-##p text portions in Shift.
After the shift datetimes are computed the data can be joined in this manner:
patients
join
provider
on
patients.date between provider.shift_start and provider.shift_end
& patients.provider = provider.provider
Example
data provider;
attrib
date informat=mmddyy10. format=mmddyy10.
provider length=$10
shift length=$60
;
input date& provider& shift&; datalines;
1/8/2019 Bob ED A/B 11p-7a (ED A/B)
1/10/2019 Bob ED C/D 11p-7a (ED C/D)
1/16/2019 Bob ED C 3p-12a (ED C)
1/9/2019 Sue UMC 5p-2a (UMC)
1/11/2019 Bob ED C/D 11p-7a (ED C/D)
1/13/2019 Bob ED PH/night 10p-4a (ED PH/night)
1/15/2019 Bob ED PH/night 10p-9p (ED PH/night)
1/17/2019 Bob ED PH/night 2-11a (ED PH/night)
;
data patients;
attrib
fin length=8
service_dt length=8 format=datetime20. informat=anydtdtm20.
provider length=$10
;
input FIN& service_dt& Provider&; datalines;
1 1/8/2019 23:40 Bob
2 1/9/2019 01:46 Timbo
3 1/9/2019 01:30 Bob
4 1/9/2019 05:06 Patty
5 1/9/2019 02:50 Bob
6 1/9/2019 17:23 Sue
7 1/9/2019 06:45 Mike
8 1/10/2019 01:35 Sue
;
* compute shift start and end datetimes;
* presume the shift time ranges are valid;
* this example does not deal with start and ends at noon or midnight;
data provider_range;
set provider;
rxid = prxparse('/(\d{1,2})(a|p)-(\d{1,2})(a|p)/');
if prxmatch(rxid,shift) then do;
length t1 $2 p1 $1 t2 $2 p2 $1;
t1 = prxposn(rxid,1,shift); t1n=input(t1,2.);
p1 = prxposn(rxid,2,shift);
t2 = prxposn(rxid,3,shift); t2n=input(t2,2.);
p2 = prxposn(rxid,4,shift);
select (p1||p2);
when ('aa', 'pp') do;
shift_start = dhms(date, t1n+12*(p2='p'),0,0);
shift_end = dhms(date, t2n+12*(p2='p'),0,0);
end;
when ('ap') do;
shift_start = dhms(date, t1n+0,0,0);
shift_end = dhms(date, t2n+12,0,0);
end;
otherwise /* pa */ do;
shift_start = dhms(date, t1n+12,0,0);
shift_end = dhms(date, t2n+24,0,0);
end;
end;
end;
else do;
put 'ERROR: Invalid shift, ' shift ;
delete;
end;
format shift_start shift_end datetime20.;
drop rxid t1: p1: t2: p2:;
run;
* this join does not use SAS SQL BETWEEN, the join criteria
* uses explicit construct a <= b and b <= c instead;
proc sql;
create table want as
select
provider.date as shift_date,
provider.shift,
patients.service_dt,
patients.fin,
patients.provider
from patients
join provider_range as provider
on patients.provider = provider.provider and
provider.shift_start <= patients.service_dt and
provider.shift_end >= patients.service_dt
order by
fin
;
quit;