Simple custom linked list in Fortran - Unexpected behavior - list

Question

I'm trying to create a very simple linked list "class" in Fortran. I've based my Fortran code in the following C example:
https://www.tutorialspoint.com/learn_c_by_examples/simple_linked_list_program_in_c.htm
Sometimes I compile and run the code and I get the expected output, a "list" containing nodes linking to other nodes, with the ordered values:
5, 4, 3, 2, 1
However, some other times, with the same exact code, I get something like:
5, 4, 3, 2, 4, 3, 2, 4, 3, 2, 4, 3, 2, ... ! or
5, 4, 3, 3, 3, 3, 3, 3, ...
My guess is some memory allocation issue? I'm new to Fortran and new to using pointers and I simply don't know where to start to debug these kinds of problems...
class_list.f90
MODULE CLASS_LIST
PRIVATE
TYPE :: NODE
REAL :: VALUE
TYPE(NODE), POINTER :: NEXT
END TYPE
TYPE, PUBLIC :: LIST
TYPE(NODE), POINTER :: HEAD
CONTAINS
PROCEDURE :: APPEND
END TYPE
CONTAINS
SUBROUTINE APPEND(THIS, VALUE)
CLASS(LIST), INTENT(INOUT) :: THIS
REAL, INTENT(IN) :: VALUE
TYPE(NODE), ALLOCATABLE, TARGET :: LINK
ALLOCATE(LINK)
LINK.VALUE = VALUE
LINK.NEXT => THIS.HEAD
THIS.HEAD => LINK
END SUBROUTINE
END MODULE
main.f90
PROGRAM MAIN
USE CLASS_LIST
TYPE(LIST) :: A
INTEGER :: I
DO I = 1, 5, 1
CALL A.APPEND(REAL(I))
END DO
END PROGRAM
Expected behavior (main local variables in Visual Studio):
Unexpected behavior example (main local variables in Visual Studio):

Answer 1

You have three problems, as suggested in the comments
In Fortran the structure component selector is %, NOT . . Thus your program contains syntax errors
In Fortran when an allocatable array goes out of scope it is automatically deallocated, unless it has the save attribute. This is a good thing as it means memory leaks using allocatable arrays are not possible, but it hurts you here as when you exit the append routine the array LINK is deallocated, so you lose your data. This is not what you want, and you end up with a dangling pointer - and so any behaviour is possible, including even appearing to work. You can avoid this here by using a pointer instead of an allocatable array. This works here as pointers are not deallocated automatically on going out of scope, but it does mean memory leaks and other strange behaviour is much more likely, so generally you should try to use allocatable arrays rather than pointers wherever possible.
In Fortran the initial association status of a pointer is undefined unless you initialise it. As undefined pointers can lead to strange behaviour it is best to initialise explicitly using => null()
In fact once you have fixed item 1 gfortran at least can tell you there is a problem if you turn on all the warning flags. The below contains this fix, and also a printing routine which you omit. Look at the warning produced by the compiler:
ijb#ianbushdesktop ~/work/stack $ cat link_alloc.f90
Module CLASS_LIST
Private
Type :: NODE
Real :: Value
Type(NODE), Pointer :: NEXT
End Type NODE
Type, Public :: LIST
Type(NODE), Pointer :: HEAD
Contains
Procedure :: APPEND
Procedure :: Print
End Type LIST
Contains
Subroutine APPEND(THIS, Value)
Class(LIST), Intent(INOUT) :: THIS
Real, Intent(IN) :: Value
Type(NODE), Allocatable, Target :: LINK
Allocate(LINK)
LINK%Value = Value
LINK%NEXT => THIS%HEAD
THIS%HEAD => LINK
End Subroutine APPEND
Subroutine Print( this )
Class( list ), Intent( In ) :: this
Call descend( this%head )
Contains
Recursive Subroutine descend( head )
Type( node ), Intent( In ) :: head
Write( *, '( f5.0, 1x )' ) head%value
If( Associated( head%next ) ) Then
Call descend( head%next )
End If
End Subroutine descend
End Subroutine Print
End Module CLASS_LIST
Program MAIN
Use CLASS_LIST
Type(LIST) :: A
Integer :: I
Do I = 1, 5, 1
Call A%APPEND(Real(I))
End Do
Call a%print
End Program MAIN
ijb#ianbushdesktop ~/work/stack $ gfortran -std=f2008 -Wall -Wextra -fcheck=all -O -g link_alloc.f90 -o link_alloc
link_alloc.f90:26:4:
THIS%HEAD => LINK
1
Warning: Pointer at (1) in pointer assignment might outlive the pointer target [-Wtarget-lifetime]
ijb#ianbushdesktop ~/work/stack $
The English is a little cryptic, but what it is really telling you about is point 2 above - as the array is about to be deallocated the pointer outlives what it points at. Compiler warnings are really useful, learn how to use them! Similarly the run time checks (-fcheck=all) indicate how broken everything is:
ijb#ianbushdesktop ~/work/stack $ ./link_alloc
0.
Program received signal SIGSEGV: Segmentation fault - invalid memory reference.
Backtrace for this error:
#0 0x7f470401f4af in ???
#1 0x7f4704ca3c49 in get_float_string
at ../../../gcc-7.4.0/libgfortran/io/write_float.def:1065
#2 0x7f4704ca4fe7 in write_float_0
at ../../../gcc-7.4.0/libgfortran/io/write.c:1597
#3 0x7f4704c9c9b4 in formatted_transfer_scalar_write
at ../../../gcc-7.4.0/libgfortran/io/transfer.c:2041
#4 0x7f4704c9cf4c in formatted_transfer
at ../../../gcc-7.4.0/libgfortran/io/transfer.c:2279
#5 0x40098a in descend
at /home/ijb/work/stack/link_alloc.f90:41
#6 0x4009a9 in descend
at /home/ijb/work/stack/link_alloc.f90:43
#7 0x4009d2 in __class_list_MOD_print
at /home/ijb/work/stack/link_alloc.f90:33
#8 0x400b1c in MAIN__
at /home/ijb/work/stack/link_alloc.f90:64
#9 0x400b1c in main
at /home/ijb/work/stack/link_alloc.f90:55
Segmentation fault
ijb#ianbushdesktop ~/work/stack $
Fixing points 2 and 3 above by using a pointer for the new node, and explicitly initialising the pointers, leads to
ijb#ianbushdesktop ~/work/stack $ cat link_pointer.f90
Module CLASS_LIST
Private
Type :: NODE
Real :: Value
Type(NODE), Pointer :: NEXT => Null()
End Type NODE
Type, Public :: LIST
Type(NODE), Pointer :: HEAD => Null()
Contains
Procedure :: APPEND
Procedure :: Print
End Type LIST
Contains
Subroutine APPEND(THIS, Value)
Class(LIST), Intent(INOUT) :: THIS
Real, Intent(IN) :: Value
Type(NODE), Pointer :: LINK
Allocate(LINK)
LINK%Value = Value
LINK%NEXT => THIS%HEAD
THIS%HEAD => LINK
End Subroutine APPEND
Subroutine Print( this )
Class( list ), Intent( In ) :: this
Call descend( this%head )
Contains
Recursive Subroutine descend( head )
Type( node ), Intent( In ) :: head
Write( *, '( f5.0, 1x )' ) head%value
If( Associated( head%next ) ) Then
Call descend( head%next )
End If
End Subroutine descend
End Subroutine Print
End Module CLASS_LIST
Program MAIN
Use CLASS_LIST
Type(LIST) :: A
Integer :: I
Do I = 1, 5, 1
Call A%APPEND(Real(I))
End Do
Call a%print
End Program MAIN
This compiles without warning and runs correctly repeatedly:
ijb#ianbushdesktop ~/work/stack $ gfortran -std=f2008 -Wall -Wextra -fcheck=all -O -g link_pointer.f90 -o link_pointer
ijb#ianbushdesktop ~/work/stack $ ./link_pointer
5.
4.
3.
2.
1.
ijb#ianbushdesktop ~/work/stack $ ./link_pointer
5.
4.
3.
2.
1.
ijb#ianbushdesktop ~/work/stack $ ./link_pointer
5.
4.
3.
2.
1.
ijb#ianbushdesktop ~/work/stack $ ./link_pointer
5.
4.
3.
2.
1.
ijb#ianbushdesktop ~/work/stack $ ./link_pointer
5.
4.
3.
2.
1.
ijb#ianbushdesktop ~/work/stack $ ./link_pointer
5.
4.
3.
2.
1.