Why DMD is not able to compile the following D code snippet? - d

Question

I am learning D and use run.dlang.io for debugging. The following code below runs without issues on run.dlang.io:
import std.stdio;
import std.algorithm;
import std.range;
import std.typecons;
static bool even(Tuple!(ulong, double) a) {
return (a[0] & 1) == 0;
}
void main() {
double[] arr = [31, 22, -3, 44, 51, 26, 47, 58, 19, 10];
auto res1 = arr.enumerate.filter!(even).map!(a => a[1]);
writeln(res1);
}
However, DMD32 v2.088 throws exception while compiling the exact same code dmd temp.d on Windows 10.
Error: function temp.even(Tuple!(ulong, double) a) is not callable using argument types (Tuple!(uint, "index", double, "value"))
While LDC compiler (1.18.0-beta1): (based on DMD v2.088.0 and LLVM 8.0.1) compiles the same file without issues.
run.dlang.io uses 2.087 dmd compiler and somehow it magically works, why doesn't it work on Windows?

Answer 1

On Windows your application is by default built for 32 bit. On OSX and Linux (which is what run.dlang.io is running) it's building by default for 64 bit.
Because of that, the array indices are uint and ulong respectively. In your code you used Tuple!(ulong, double), but on 32 bit it's called with uint indices.
Instead of using ulong/uint you should use size_t for indices, which maps to uint/ulong. This is defined in object.d, which is included by default.
So if you change your function to
static bool even(Tuple!(size_t, double) a) {
return (a[0] & 1) == 0;
}
it will run on both 32 bit and 64 bit.
On Windows you can also test your code with dub by running it with --arch=x86_64 or with the dmd flag -m64 where it should already work without change. I recommend testing your application both on 32 bit and 64 bit always to make sure you are using size_t where needed.