How to locate and replace a value [closed] - coldfusion

Question

Closed. This question needs to be more focused. It is not currently accepting answers.
Want to improve this question? Update the question so it focuses on one problem only by editing this post.
Closed 3 years ago.
Improve this question
I have been looking for a solution for the following:
Replace the < with the words less than, but keep the number <xx (the xx is a number like 55). For example: <55 or < 55 to less than 55.
I have not found a solution.
Mike

Answer 1

The naive way
...would be just using replace() and call it a day:
<cfscript>
s = "Is 54 < 55 and < 56?";
r = replace(s, "<", "less than", "ALL");
writeOutput(r);
</cfscript>
Returns: Is 54 less than 55 and less than 56?
But it's not that easy
...because you eventually encounter:
<cfscript>
s = "Is 54<55 and <56?";
r = replace(s, "<", "less than", "ALL");
writeOutput(r);
</cfscript>
Returns: Is 54less than55 and less than56?
We need to handle missing whitespaces around <.
Easy, we just add spaces around the needle, like this " less than ".
Are we done?
...No, it can always get worse. Look at this:
<cfscript>
s = "Is <b>54</b><55 and < 56?";
r = replace(s, "<", " less than ", "ALL");
writeOutput(r);
</cfscript>
Returns: Is less than b>54 less than /b> less than 55 and less than 56?
We need to actually detect if the > character is in front of a digit.
The fix
...is called regular expression. And reReplace() the name of the function we need:
<cfscript>
s = "Is <b>54</b> <55 and < 56?";
r = reReplace(s, "<\s*([0-9])", "less than \1", "ALL");
writeOutput(r);
</cfscript>
Returns: Is <b>54</b> less than 55 and less than 56?
Breakdown of the regex:
<
pattern starts with <
\s*
any whitespace (\s), can be missing or present in any number (*)
([0-9])
we are capturing any digit [0-9] using brackets
In the needle we replace everything that was not captured with less than and bring back the captured digit using \1. As a sideffect, we also removed any additional whitespaces in front of the digit, since we only captured the digit itself and replaced everything between < and the digit.
You could preserve the whitespaces in front by extending the capture and there also might be a need to tackle something like 54< 55 to result in 54 less than 55. Once you understand how regex capturing works, this won't be a problem for you.