how to get flag and dateformates in sas - sas

Question

Hi I have one doubt in sas
in dataset date format have 08-04-1988
base on this values I want create date styles and along flag values
For datetime flag creation if dateandtime have then consider flag 1 else 0
for date if date have then consider flag 1 else 0
for time if time have then consider flag 1 else 0
DATA DAT;
X= "08APR1988"D;
FORMAT X DDMMYYD10.;
RUN;
Based on above value I want output like below
Datetime | Date | Time | DatetimeFlag | DateFlag |TimeFlag
08APR1988 00:00:00 |08-04-1988 |00:00:00 | 0 |1 |0
I tried like below
DATA DUMM;
SET DAT;
DT=PUT( X, DDMMYY10.);
DATEF=PUT( X, date9.);
DTs=PUT( X, DATETIME32.);
TimeF=PUT( X, TIME.);
RUN;
here if donot have time then its takeing default datewith time similar time also
i want display if time is not available then consider 00:00:00 similar if date not available the date aslo : 1960-01-01
but above scirpt is not given expeted result ,
can you please tell me how to wirte sas coding to achive this task.

Answer 1

SAS has two value types, numeric and character.
Date and DateTime values are numeric with handling.
Date values are the number of days since 01JAN1960.
DateTime values are the number of seconds since 01JAN1960.
Non-integer date values do not get special interpretation (in other date systems, such as Excel, the decimal part of a numeric is the fraction of the day as well)
Non-integer DateTime values are fractional seconds.
You can convert the date to datetime by multiplying by the number of seconds in a day (86,400)
Suppose you had a non-integer date value, such as
data _null_;
D = '01JAN2019'D + 0.5;
format D yymmdd10.;
put D= / D=best12.;
DT = D * 86400;
format DT datetime21.2;
put DT= / DT=best12.;
run;
---------- LOG ----------
D=2019-01-01
D=21550.5
DT=01JAN2019:12:00:00.00
DT=1861963200
You can separate out the date and time parts of a datetime value using the functions DATEPART and TIMEPART
data have;
dt = '01FEB2019:12:34:56.78'DT; output;
dt = '15FEB2019:00:00:00'DT; output;
format dt datetime21.2;
run;
data want;
set have;
d = datepart (dt);
t = timepart (dt);
format d yymmdd10.;
format t time12.2;
dt_is_just_date = (t eq 0);
dt_has_time_part = (t ne 0);
run;
proc print data=want;
run;
-------
dt_is_ dt_has_
just_ time_
Obs dt d t date part
1 01FEB2019:12:34:56.78 2019-02-01 12:34:56.78 0 1
2 15FEB2019:00:00:00.00 2019-02-15 0:00:00.00 1 0