jump to next by group when condition is met - sas

Question

I have a file documenting changes in marital status - ID, type of change (marriage, divorce, being widowed) and year (and month) of change. I want to calculate each person's marital status (married, divorced, widow(er), never been married) for any given year. Since a person can go through many changes and my file is around 20 million rows I'd like to skip to the next person when I find the answer and not continue through all of that person's other records.
I thought to sort by ID and descending date of change and then set by ID. For each ID, if the year I'm interested in is greater than (or equal to) the year of change then calculate marital status and output the ID and marital status. If not, continue to the next record until the condition is met. If no record meets the condition then marital status=never been married.
data a;
length type_change $10;
input ID type_change yr_change mnth_change;
cards;
1 marriage 2006 9
1 divorce 2010 5
10 marriage 2005 2
10 divorce 2012 10
10 marriage 2016 8
23 marriage 2017 6
35 marriage 2002 7
35 widow 2013 12
;
run;
For 2015 I'd like to get:
- ID marital_status
- 1 divorced
- 10 divorced
- 23 never been married
- 35 widowed
Thanks in advance!

Answer 1

/* do this sort only once and save sorted */
proc sort data = have out = sorted;
by id yr_change;
run;
proc sort data = have (keep =id) out = ids nodupkey;
by id;
run;
data step1;
set sorted;
where yr_change <= &y;
by id;
if last.id;
run;
data want;
merge step1 (in =a) ids (in =b);
by id;
if b and not a then status = "never married";
else status = type_change;
run;

Answer 2

If by skip you mean not reading them then you cannot "skip" observations. But you can ignore them by using IF statement (or other conditional logic).
Using RETAIN and BY group processing should get you answer.
%let year=2015;
data want ;
set a ;
by id yr_change mnth_change ;
length status $20;
retain status ;
if first.id then status='never been married ';
if yr_change <= &year then status=type_change ;
if last.id;
keep id status;
run;
Result:
Obs ID status
1 1 divorce
2 10 divorce
3 23 never been married
4 35 widow
If you have access to a master list of ID's you could convert to using a WHERE statement which MIGHT reduce the I/O needed to process all of the records. For example merge the list of ID's with a subset of the marital status change records.
data want;
merge id_list a(in=in2 where=(yr_change <= &year));
by id;
length status $20;
retain status ;
if first.id then status='never been married ';
if in2 then status=type_change ;
if last.id;
keep id status;
run;

Answer 3

A DOW loop will let you compute a result over a group. An implicit output will save the result computed for the group. Because the result is dependent on your year of interest, you will want to track that also in any created data sets.
%let YEAR_CUTOFF = 2015;
data want (keep=id status year_cutoff);
attrib
id length = 8
status length=$20 label="Status at year end &YEAR_CUTOFF"
year_cutoff length = 8
;
retain year_cutoff &YEAR_CUTOFF;
status = 'never been married';
do until (last.ID); /* The DOW loop */
set have (rename=status=status_of_interest);
by id;
if year <= &YEAR_CUTOFF then status = status_of_interest;
end;
/* No explicit OUTPUT in the step, so,
* an implicit OUTPUT occurs here at the bottom of the step
*/
run;

Answer 4

Then use retain statement.
Extract all IDs:
proc sort data=a out=ids(keep= id) nodupkey ;
by id;
run;
Generate all years that you need to all IDs
data years;
set ids;
must_be_date=2000;
do i = 1 to 20;
must_be_date+1;
output;
end;
drop i;
run;
Join by condition:
proc sql;
create table res as
select *
from years left join a on years.must_be_date = a.yr_change and a.id = years.id
;
run;
proc sort ;
by id must_be_date;
run;
Use retain:
data res;
retain temp "never been married";
set res;
by id must_be_date;
if first.id then temp="never been married";
if type_change="" then type_change = temp;
else temp=type_change;
run;
to check :
data res_2015;
set res;
where must_be_date=2015;
run;
Result table:
+--------------------+----+--------------+-------------+-----------+-------------+
| temp | ID | must_be_date | type_change | yr_change | mnth_change |
+--------------------+----+--------------+-------------+-----------+-------------+
| divorce | 1 | 2015 | divorce | . | . |
| divorce | 10 | 2015 | divorce | . | . |
| never been married | 23 | 2015 | never been | . | . |
| widow | 35 | 2015 | widow | . | . |
+--------------------+----+--------------+-------------+-----------+-------------+