Loop through XML file and select only specific nodes - xslt

Question

I have the following JSON file which I would like to transform via XSLT.
[
{
"firstName": "John",
"lastName": "Andy",
"age": "15"
},
{
"firstName": "Ann",
"lastName": "Heather",
"age": "13"
}
]
and have the following result:
[
{
"firstName": "John",
"lastName": "Andy"
},
{
"firstName": "Ann",
"lastName": "Heather"
}
]
What I do is transform the JSON to XML and then manipulate the file using the following code:
<xsl:param name="json" as="xs:string">
<xsl:template match="/*" name="xsl:initial-template">
<xsl:variable name="input-as-xml" select="json-to-xml($json)"/>
<xsl:variable name="transformed-xml" as="element(array)">
<array xmlns="http://www.w3.org/2005/xpath-functions">
<xsl:for-each select="/node()">
<map xmlns="http://www.w3.org/2005/xpath-functions">
<string key="firstName">
<xsl:value-of select="$input-as-xml//string[#key='firstName']"/>
</string>
<string key="lastName">
<xsl:value-of select="$input-as-xml//string[#key='lastName']"/>
</string>
</map>
</xsl:for-each>
</array>
</xsl:variable>
<xsl:value-of select="xml-to-json($transformed-xml)"/>
</xsl:template>
My output using the above code is:
[
{
"firstName": "John Ann John Ann",
"lastName": "Andy Heather Andy Heather"
}
]
I would need some help to change my code to retrieve the information I need to the way expected.

Answer 1

I would strongly suggest to stick with the approach suggested in the answer to your previous question, that is, to push the json-to-xml result through templates, that way you just need an empty template to delete the age:
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:xs="http://www.w3.org/2001/XMLSchema"
xpath-default-namespace="http://www.w3.org/2005/xpath-functions"
xmlns="http://www.w3.org/2005/xpath-functions"
exclude-result-prefixes="#all"
version="3.0">
<xsl:param name="json" as="xs:string">
[
{
"firstName": "John",
"lastName": "Andy",
"age": "15"
},
{
"firstName": "Ann",
"lastName": "Heather",
"age": "13"
}
]
</xsl:param>
<xsl:output method="text"/>
<xsl:template match="/" name="xsl:initial-template">
<xsl:variable name="transformed-json-xml">
<xsl:apply-templates select="json-to-xml($json)/node()"/>
</xsl:variable>
<xsl:value-of select="xml-to-json($transformed-json-xml, map { 'indent' : true() })"/>
</xsl:template>
<xsl:mode on-no-match="shallow-copy"/>
<xsl:template match="string[#key = 'age']"/>
</xsl:stylesheet>
https://xsltfiddle.liberty-development.net/bnnZWD/11

Answer 2

Your xsl:for-each isn't setting the context correctly. I think you probably want:
<xsl:for-each select="$input-as-xml/*/*">
<map xmlns="http://www.w3.org/2005/xpath-functions">
<string key="firstName">
<xsl:value-of select="string[#key='firstName']"/>
</string>
<string key="lastName">
<xsl:value-of select="string[#key='lastName']"/>
</string>
</map>
</xsl:for-each>
But I think you can simplify it using xsl:copy-of:
<xsl:for-each select="$input-as-xml/*/*">
<map xmlns="http://www.w3.org/2005/xpath-functions">
<xsl:copy-of select="*[#key=('firstName', 'lastName')]"/>
</map>
</xsl:for-each>