%SCAN with M modifier giving incorrect results - sas

Question

Can anyone please suggest why do the below two codes have different outputs?
I have a macro var FILETYPE which resolves to ,File // missing first value.
%let b=%scan("&filetype",1,",",M);
%put &b;
%let c=%scan("&filetype",2,",",M);
%put &c;
%let d=%scan("&filetype",3,",",M);
%put &d;
%mend;
%tt;`
I get the following output:
SYMBOLGEN: Macro variable FILETYPE resolves to ,File
SYMBOLGEN: Macro variable B resolves to
SYMBOLGEN: Macro variable FILETYPE resolves to ,File
SYMBOLGEN: Macro variable C resolves to
SYMBOLGEN: Macro variable FILETYPE resolves to ,File
SYMBOLGEN: Macro variable D resolves to File
File
When macro var C should have resolved to File , but its still NULL and D gets the value File.
The same logic in a plain datastep works correctly.
data a;
b=scan("&filetype",1,',','M');
c=scan("&filetype",2,',','M');
run;
Output :
b=blank
c=File
Can someone please suggest how come the SCAN function with M modifier work okay in data step but not in macro?

Answer 1

It works exactly the same in macro code as in data step code. The problem is that you added double quotes to both the string to be scanned and to the list of delimiters to use. So the equivalent data step would be:
%let filetype=A,B;
data _null_;
length string word $100;
string=quote(symget('filetype'));
do i=1 to 4;
word=scan(string,i,'","','M');
put i= word=:$quote.;
end;
run;
Which produces this result:
i=1 word=""
i=2 word="A"
i=3 word="B"
i=4 word=""
What you probably meant to do in macro code was:
%scan(%superq(filetype),1,%str(,),M)
In normal SAS code you need to add quotes around string literals so that the parser knows that you didn't mean a variable name. In macro code that is not needed, everything is a string. You use macro triggers, & and %, to let the parser know when to treat it differently.
When generating a delimited list to be used in macro code then generate it with a different delimiter and avoid all of the macro quoting needed to deal with the commas.
... into :filetype separated by '|' ...
%scan(&filetype,1,|,m)

Answer 2

Don't double quote the arguments in macro invocations. You DO need to literalize the comma valued argument as %str(,) in order to have it NOT be considered an argument separator.
%scan ( &filetype , 1, %str(,), M )
If the filetype value contains macro important symbols, you may have to macro quote or superq the argument. If the return can contain macro important symbols that are not to be resolved you will want to use %QSCAN to mask them.