How can I extract data from dat file? - fortran

Question

I want to extract values in 1,3,5,9,11,.... lines of my .dat file using a fortran code.This is my code
program one
integer x, y, z
open (unit=10, file='try.dat', status='old')
open (unit=20, file='run_energy.dat', status='unknown')
dimension time(40), energy(40)
do y=1,13
z=2*(y-1)
do x=(z+1),(z+1)
read (10,*) time(x), energy(x)
write(20,*) time(x), energy(x)
end do
end do
stop
end
~
But, I don't get the values correspond to the lines I mentioned above. Can you please anyone help me.
Thank you.

Answer 1

You need to skip line (dummy read). Something like this:
x = 1
do i=1,13
! Read only if at correct line of 'try.dat'
if (i == 2*(x-1)+1) then
read (10,*) time(x), energy(x)
write(20,*) time(x), energy(x)
! Increment x
x=x+1
else
! Skip line
read (10,*)
end if
end do
Kind regards.

Answer 2

As already mentionned, the trick is to skip one line of the input file try.dat in order that only odd lines are written to the output file run_energy.dat.
Therefore the FORTRAN solution might also look like this, if the odd values of the input file shall be saved in the vectors time and energy:
program one
implicit none
integer, parameter :: siz = 40
integer :: x, st
real :: time(siz), energy(siz)
character :: line*256
open (unit=10, file='try.dat', status='old')
open (unit=20, file='run_energy.dat', status='unknown')
x = 1
read(10,'(A)',iostat=st) line
do while ((st == 0).and.(x < siz))
write(*,*) 'x = ',x, ', line = ', trim(line)
read(line,*,iostat=st) time(x), energy(x)
if (st == 0) write(20,*) time(x), energy(x)
read(10,'(A)',iostat=st) line ! Skip one line
if (st == 0) then ! Read next relevant line
x = x + 1
read(10,'(A)',iostat=st) line
endif
end do
close(10)
close(20)
end
If no saving of data into these vectors is required then the solution is quite shorter:
program one
implicit none
integer :: st
character :: line*256
open (unit=10, file='try.dat', status='old')
open (unit=20, file='run_energy.dat', status='unknown')
read(10,'(A)',iostat=st) line
do while (st == 0)
write(20,'(A)') trim(line)
read(10,'(A)',iostat=st) line ! Skip one line
if (st == 0) then ! Read next relevant line
read(10,'(A)',iostat=st) line
endif
end do
close(10)
close(20)
end
The trick is to use iostat in the read statement to detect end of file or improper matches of the line data to the vectors time and energy.
Hope it helps.