Calculating the average with different conditions - powerbi

Question

I have started to learn some basic usage in Power BI and need help in solving a problem.
Please see my table attached.
I want to calculate the average of the percentage of the last entry with the last "Status 1" for each ID. In my database there are some ID's in which the Status "Status 1" is just contained once (like ID 4) - I would like to exclude those ID's. Is that possible?
For this example it would be:
(94 + 82 + 85) / 3 = 87
I have started with trying to calculate the average of all "Percent" for all "Status 1".
Test Average 2 =
CALCULATE (
AVERAGEX(Tabelle1; Tabelle1[Percent]);
FILTER ( ALL ( Tabelle1 ); Tabelle1[Status]="Status 1" );
ALL (Tabelle1)
)
How do I proceed? I don't know how to create the code with so many conditions. I have tried to research the solution but gave up. I hope you can help me and would appreciate the help for a Coding beginner :)
Thanks in advance,
Jenny

Answer 1

First, welcome to the Power BI family!
Second, here is how I would approach your problem...
1. Create a "DateTime" column
Since we need to check for the latest entry, and presumably you want that checked based on date and time, it is easier if there is only one column to check).
In the ribbon, go to Modeling -> New Column.
In the formula bar that pops up, enter the following formula. Power BI can recognize the date and time columns for what they are and since they are both elements of date/time, Power BI lets us do simple addition. The - 1 in the formula is to account for the "day" that is associated with the time.
DateTime = [Date] + [Time] - 1
2. Create Average Measure
Here is the whole formula first and following is a breakdown piece by piece.
Last Percent Average =
VAR TargetStatus = "Status 1"
VAR IDsWithMoreThanOneStatus1 = FILTER('Data', COUNTROWS(FILTER('Data', IFERROR(SEARCH(TargetStatus, [Status]), -1) > 0 && [ID] = EARLIER([ID]))) > 1)
VAR LastStatus = FILTER(IDsWithMoreThanOneStatus1, IFERROR(SEARCH(TargetStatus, [Status]), -1) > 0 && [DateTime] >= MAXX(FILTER('Data', IFERROR(SEARCH(TargetStatus, [Status]), -1) > 0 && [ID] = EARLIER([ID])), [DateTime]))
RETURN
DIVIDE(SUMX(LastStatus, [Percent]), COUNTROWS(LastStatus), BLANK())
The first chunk of the measure is defining variables. Variables are super useful and I would encourage you to at least take a quick look at them. Here's just one article on them.
The first variable is simply designating the target status (in case you ever want to change it). This variable is optional as if it will never change, you could just put the text into the other formulas.
VAR TargetStatus = "Status 1"
The second variable filters the master list of data to only those IDs with more than one "Status 1" (excluding ID = 4 in this case). One of the keys with this variable is the EARLIER function. While it is horribly named (in my opinion), it is immensely useful. You can read the official documentation on it here.
Step by step through the variable: We want to filter the Data table... where the row count is greater than one... when we filter the table to include "Status 1" for the specified ID.
The SEARCH function will look at the entire string and tell us the starting position of our search string (TargetStatus). We need to wrap it in an IFERROR function to handle cases where TargetStatus does not show up in the [Status] value. Then we just check to see if the result is greater than 0 indicating that the TargetStatus is in the [Status] value.
VAR IDsWithMoreThanOneStatus1 =
FILTER(
'Data',
COUNTROWS(
FILTER(
'Data',
IFERROR(SEARCH(TargetStatus, [Status]), -1) > 0 &&
[ID] = EARLIER([ID])
)
) > 1
)
The third variable filters the list from the second variable to capture the last "Status 1" for each ID. This uses the same thought process as the second variable: we want to filter the table (from the second variable) where the status = "Status 1" and the [DateTime] is greater than or equal to the max [DateTime] for all "Status 1" for the specified ID.
VAR LastStatus =
FILTER(
IDsWithMoreThanOneStatus1,
IFERROR(SEARCH(TargetStatus, [Status]), -1) > 0 &&
[DateTime] >= MAXX(
FILTER(
'Data',
IFERROR(SEARCH(TargetStatus, [Status]), -1) > 0 &&
[ID] = EARLIER([ID])
),
[DateTime]
)
)
The RETURN keyword is just telling Power BI that we are done defining variables and that everything else in the formula defines the actual value that is returned for this measure.
RETURN
Lastly is the average itself. In this case, we'll use SUMX to sum up all of the [Percent]s from the third variable, and then divide it by the row count of the third variable. I would always recommend using the DIVIDE function as it handles for dividing by 0 and other errors.
DIVIDE(
SUMX(
LastStatus,
[Percent]
),
COUNTROWS(LastStatus),
BLANK()
)
When it's all said and done, your measure will give the desired result.