Lookup previous value based on criteria from another column - powerbi

Question

Objective:
Get the previous value based on a criteria.
Situation:
I have a table with groups numbered 1,2. I would like to look at the previous value (referring to the previous date) but for each group.
Desired Output:
My output should look like this
+------------+-------+-------+----------------+
| date | group | value | previous value |
+------------+-------+-------+----------------+
| 2019-02-02 | 2 | 50 | 45 |
| 2019-02-02 | 1 | 60 | 80 |
| 2019-01-18 | 2 | 45 | |
| 2019-01-18 | 1 | 80 | |
+------------+-------+-------+----------------+
What I tried:
previous value =
LOOKUPVALUE(
Table[value],
Table[date],
CALCULATE(
MAX(Table[date]),
FILTER(
Table,
Table[group]=EARLIER(Table[group]) && Table[date]<EARLIER(Table[date])
)
)
)

Answer 1

As I understand, you want this as a calculated column, not a measure. Try:
Previous Value =
VAR Current_Date = Table[date]
VAR Previous_Date =
CALCULATE (
MAX ( Table[date] ),
Table[date] < Current_Date,
ALLEXCEPT ( Table, Table[group] )
)
RETURN
CALCULATE (
MAX ( Table[value] ),
Table[Date] = Previous_Date,
ALLEXCEPT ( Table, Table[group] )
)
How it works:
We iterate each record of the Table and store its date in "Current_Date" variable.
For each record, find previous date, which is the max date that is smaller than the date of the record we are iterating. To do that, we need to have access to all dates, not only the date of the current record, so we need to use ALL function. However, since we need to do it by group, we use ALLEXCEPT, which preserves filter for the current group.
Once previous date is found, you can use exactly the same pattern to find previous value - find MAX value where record's date equals previous date, while preserving group filter.