How to append to string in ocaml? - ocaml

Question

I don't know how to add some string to itself in loop.
let parameters = [| [| ("name", "fdjks"); ("value", "dsf") |]; [| ("name", "&^%"); ("value", "helo") |] |] ;;
let boundary = "----WebKitFormBoundary7MA4YWxkTrZu0gW";;
let body = "";;
for x = 0 to (Array.length(parameters) : int)-1 do
let (_, paramName) = parameters.(x).(0) in
let (_, paramValue) = parameters.(x).(1) in
body = body ^ "--" ^ boundary ^ "\r\n" ^ "Content-Disposition:form-data; name=\"" ^ paramName ^ "\"\r\n\r\n" ^ paramValue ;
print_endline(body)
done;;
but this gives error..
Any way to do this......?

Answer 1

The (^) operator concatenates two strings, e.g.,
# "hello" ^ ", " ^ "world!";;
- : string = "hello, world!"
If you have a list of strings, then you can use the String.concat function, that takes a separator, and a list of strings and produces there concatentation in an effective way:
# String.concat ", " ["hello"; "world"];;
- : string = "hello, world"
Why is using the (^) operator in a cycle is a bad idea? Every concatentation creates a new string and then copies the contents of both strings into the new string. So appending N strings will end up in approximately n^2 copying (where n is the length of a string). The same is true in Java and other languages/libraries where concatenation returns a new string, instead of mutating one of its arguments. A usual solution is to use the StringBuilder pattern, which in OCaml is represented with the Buffer module. So suppose, you don't have the String.concat function, and you would like to build your own efficient concatenation function (this could also be useful, since Buffer is a more general solution than String.concat, and will work when, for example, you input is not a list). Here is our implementation,
let concat xs =
let buf = Buffer.create 16 in
List.iter (Buffer.add_string buf) xs;
Buffer.contents buf
This function will create a buffer that will automatically resize itself. The 16 is just an initial guess and could be any number. On the second line we just iterate over all strings and push the to the buffer, and finally, we ask the buffer to build the resulting string. Here is how we use this function:
# concat ["hello"; ", "; "world"];;
- : string = "hello, world"

Answer 2

In OCaml variables are immutable by default. You need to use a reference if you want to change the value of a variable.
let parameters = [| [| ("name", "fdjks"); ("value", "dsf") |]; [| ("name", "&^%"); ("value", "helo") |] |] ;;
let boundary = "----WebKitFormBoundary7MA4YWxkTrZu0gW";;
let body = ref "";;
for x = 0 to (Array.length(parameters) : int)-1 do
let (_, paramName) = parameters.(x).(0) in
let (_, paramValue) = parameters.(x).(1) in
body := !body ^ "--" ^ boundary ^ "\r\n" ^ "Content-Disposition:form-data; name=\"" ^ paramName ^ "\"\r\n\r\n" ^ paramValue ;
print_endline(!body)
done;;
See also add elements to list in a loop in OCaml.
Please note that adding two strings in OCaml is an O(n) operation (n = number of characters), making it rather expensive for long strings. You can use the Buffer module to concatenate strings efficiently. Using ^, however, is much more readable.
A good compromise between readability and efficiency is probably, using the Buffer module for long and using ^ for short strings. Hence, using a Buffer for your outer iteration would be a good idea. The code looks as follows.
let parameters = [| [| ("name", "fdjks"); ("value", "dsf") |];
[| ("name", "&^%"); ("value", "helo") |] |] ;;
let boundary = "----WebKitFormBoundary7MA4YWxkTrZu0gW";;
let body = Buffer.create 256;;
for x = 0 to (Array.length(parameters) : int)-1 do
let (_, paramName) = parameters.(x).(0) in
let (_, paramValue) = parameters.(x).(1) in
Buffer.add_string body
("--" ^ boundary ^ "\r\n"
^ "Content-Disposition:form-data; name=\""
^ paramName ^ "\"\r\n\r\n" ^ paramValue);
print_endline(Buffer.contents body)
done;;

Answer 3

Iterating recursively with an accumulator is the idiomatic way to do what you want in ocaml:
let parameters = [| [| ("name", "fdjks"); ("value", "dsf") |]; [| ("name", "&^%"); "value", "helo") |] |] ;;
let boundary = "----WebKitFormBoundary7MA4YWxkTrZu0gW" ;;
let len = Array.length(parameters) ;;
let rec loop accum index =
if index < len then
let (_, paramName) = parameters.(index).(0) in
let (_, paramValue) = parameters.(index).(1) in
loop (accum ^ "--" ^ boundary ^ "\r\n"
^ "Content-Disposition:form-data; name=\""
^ paramName ^ "\"\r\n\r\n" ^ paramValue)
(index + 1)
else print_endline accum
in
loop "" 0 ;;
Or better still look at the Array.fold_left function.
let parameters = [| [| ("name", "fdjks"); ("value", "dsf") |]; [| ("name", "&^%"); ("value", "helo") |] |] ;;
let boundary = "----WebKitFormBoundary7MA4YWxkTrZu0gW";;
let () = print_endline
(Array.fold_left
(fun acc elt ->
let (_, paramName) = elt.(0) in
let (_, paramValue) = elt.(1) in
acc ^ "--" ^ boundary ^ "\r\n"
^ "Content-Disposition:form-data; name=\""
^ paramName ^ "\"\r\n\r\n" ^ paramValue)
""
parameters)