Date Format in Base SAS - sas

Question

I have to pass Date format in Proc SQL in the where Class.
Date Format is like this "SAT Mar 17 01:29:17 IST 2018" (String Column, length is 28)
Now when i have tried input(Date,datetime18.) and some other date functions, but all are giving me error. Below is my query
proc sql;
Select input(Date,datetime18.) from table;
quit;
How to convert this date into simple date like "17-03-2018", so that i can use the same in proc SQL query?

Answer 1

date is numeric and you should not compare it with string value, compare it with date literal by converting your value also to date. comparing greater and less than values with strings, in general do not serve any purpose and can lead to erroneous results. less than and greater than have meaning/make sense when you compare numeric variables
data have;
b = "SAT Mar 17 01:29:17 IST 2018";
output;
b= "SAT Mar 19 01:29:17 IST 2018";
output;
b= "SAT Jun 20 01:29:17 IST 2018";
output;
b= "SAT Mar 25 01:29:17 IST 2018";
output;
run;
proc sql;
select * from have
where input(cats(scan(b,3),scan(b,2), scan(b, -1)),date9.) > "19Mar2018"d;

Answer 2

The ANYDTDTM can be a go to informat in many cases, however, as you point out (in comments) it is not so for the datetime format presented in the question.
The string can be re-arranged into a SAS inputable date time representation using cats and scan
data have;
date_string = "SAT Mar 17 01:29:17 IST 2018";
run;
data want;
set have;
dt_wrong = input(date_string, anydtdtm.);
dt_right = input ( cats
( scan(date_string,3),
scan(date_string,2),
scan(date_string,6),':',
scan(date_string,4)
), datetime20.);
put date_string= /;
put dt_right= datetime20. " from input of cats of string parts";
put dt_wrong= datetime20. " from anydttm ";
run;
* sample macro that can be applied in data step or sql;
%macro dts_to_datetime(dts);
input ( cats
( scan( &dts , 3),
scan( &dts , 2),
scan( &dts , 6), ':',
scan( &dts , 4)
)
, datetime20.)
%mend;
data want2;
set have;
dt_righton = %dts_to_datetime(date_string);
format dt_righton datetime20.;
put dt_righton=;
run;
The macro can also be used in where statements such as
where '18-Mar-2018:0:0'DT <= %dts_to_datetime (date_string)
Or SQL
, %dts_to_datetime (date_string) as event_dtm format=datetime20.

Answer 3

i have used sub-string.I created a new column NEW_DATE in Dataset. As mentioned above date format is Sat Mar 17 01:01:01 IST 2018. Below is the data step to fetch date in the format of DD-MMM-YYYY
data new;
set old;
new_date = substr(date,9,2)||"-"||substr(date,5,3)||"-"||substr(date,25,4);
new_date_updated = input(new_date,date11.);
format new_date_updated date11.;
run;
then i use new column in proc sql
proc sql;
select * from new where new_date_updated>'17-Mar-2018'd;
quit;
and it worked for me.
Thanks
Checked above approach with all scenarios, working fine with all