Replace string with another string - replace

Question

I would like to replace the current month to another month while everything else stay the same.
I have hundred over files which I thought of using rename function in CMD.
My file before is apple Oct'18 banana.xlsx, I want change is it to 'apple Nov'18 banana.xlsx'
The closest I gotten was using Ren *oct*.xlsx "* Nov'18 banana*".xlsx
but the result I got in return was apple Oct Nov banana.xlsx
However, I cannot replace the Oct completely.

Answer 1

Try ren *.xlsx ??????Nov??????????.*
* is a wildcard to match every ".xlsx" extension.
? is a wildcard to make every character in the original file stay unchanged.

Answer 2

I think there is no way to accomplish your task by a single ren command line.
You could write a batch file with the following code and name it ren_date.bat:
#echo off
setlocal EnableExtensions DisableDelayedExpansion
rem // Define constants here:
set "_ROOT=." & rem // (root directory; `.` is current, `%~dp0.` is parent)
set "_FROM=%~1" & rem // (name portion to be replaced; `%~1` is 1st argument)
set "_TO=%~2" & rem // (name portion to be inserted; `%~2` is 2st argument)
rem // Enumerate all matching files (note the SPACE behind the asterisk):
for /F "delims=| eol=|" %%J in ('dir /B /A:-D "%_ROOT%\* %_FROM%*.xlsx"') do (
rem // Store current file name, initialise variable for new name:
set "FILE=%%J" & set "NAME="
rem // Toggle delayed expansion to avoid loss of exclamation marks:
setlocal EnableDelayedExpansion
rem /* Replace each SPACE in current file name by `" "` and enclose the
rem whole string in between `""`, so we get a list of quoted items,
rem which reflect all the SPACE-separated file name parts: */
for %%I in ("!FILE: =" "!") do (
endlocal
rem // Store current file name part:
set "PART=%%~I"
setlocal EnableDelayedExpansion
rem /* Assemble new name, performing the intended substitution of the
rem predefined sub-strings; the `for /F` loop is needed to transport
rem the resulting new file name over the `endlocal` barrier: */
for /F "delims=| eol=|" %%K in ("!NAME! !PART:%_FROM%=%_TO%!") do (
endlocal
rem // Store the assembled name portion:
set "NAME=%%K"
setlocal EnableDelayedExpansion
)
)
rem // Now rename file to the assembled new name:
ren "!_ROOT!\!FILE!" "!NAME:~1!"
endlocal
)
endlocal
exit /B
Then run it in cmd using the following command lines, given that you are in the directory that contains the files to rename:
ren_date.bat "Oct'18" "Nov'18"
Referring to the example from my answer to a former question of yours, this should rename the files:
and some pears Oct'18_xyz.xlsx
apples Oct'18.xlsx
bananas Oct'18.xlsx
more fruit Oct'18_xyz.xlsx
oranges Oct'18.xlsx
plus peaches Oct'18_xyz.xlsx
strawberries Oct'18 abcdef.xlsx
To these ones:
and some pears Nov'18_xyz.xlsx
apples Nov'18.xlsx
bananas Nov'18.xlsx
more fruit Nov'18_xyz.xlsx
oranges Nov'18.xlsx
plus peaches Nov'18_xyz.xlsx
strawberries Nov'18 abcdef.xlsx
(To write the above code into a command line directly in cmd is not possible, I believe, particularly due to the toggling of delayed expansion to make the code safe.)

Answer 3

As batch only knows the variable type string ad isn't good at date time calculations,
I suggest to use PowerShell for this.
With the
[datetime] type and
the .AddMonths() method
the Regular expression based -match operator
it will do even crossing year boundaries:
## Q:\Test\2018\12\13\SO_53757192.ps1
$CI = [cultureinfo]::InvariantCulture
$dt = ' MMM\''yy '
Get-ChildItem '* ???''[0-9][0-9] *.xlsx' |
Where-Object BaseName -match ' (Jan|Feb|Mar|Apr|Jun|Jul|Aug|Sep|Oct|Nov|Dec)''(\d{2}) ' |
Rename-Item -NewName {$_.Name -replace $Matches[0],
[datetime]::ParseExact($matches[0],$dt,$CI).AddMonths(1).ToString($dt)} # -WhatIf
You can invoke it from batch as a file
powershell -NoP -Ex bypass -File ".\SO_53757192.ps1"
Or cram it into one line
powershell -NoP -C "$CI=[cultureinfo]::InvariantCulture;$dt=' MMM\''yy ';Get-ChildItem '* ???''[0-9][0-9] *.xlsx'|Where-Object BaseName -match ' (Jan|Feb|Mar|Apr|Jun|Jul|Aug|Sep|Oct|Nov|Dec)''(\d{2}) '|Rename-Item -NewName {$_.Name -replace $Matches[0],[datetime]::ParseExact($matches[0],$dt,$CI).AddMonths(1).ToString($dt)}"