Output a Report from sas - sas

Question

Hello I need to output a dat file from my sas code , something like:
#################################
###Game Of Thrones
################################
Number of Candidates = 1
################################
Number of Games = 3
################################
Controlppt = 1
Controlgame = 2
################################
# PPt 1 = Abc
# PPt 2 = Bcd
1|2|a|1|3|b1|2|a|1|3|b1|2|a|1|3|b1|2|a|1|3|b
1|2|a|1|3|b1|2|a|1|3|b1|2|a|1|3|b1|2|a|1|3|b
################################
So, It's a mix of comments and text and underneath is pipe delimited data.
I tried using proc export but none of the titles are printed, I also tried with Ods and using title statement for each comment, but does not work either.
Can anyone please suggest a way to achieve this?

Answer 1

You didn't say what your dataset looks like. So let's just invent one.
data have ;
ncandidates=1; ngames=3; controlppt=1; controlgame=2;
ppt1='Abc'; ppt2='Bcd';
infile cards dsd dlm='|';
input (var1-var21) ($);
cards;
1|2|a|1|3|b1|2|a|1|3|b1|2|a|1|3|b1|2|a|1|3|b
1|2|a|1|3|b1|2|a|1|3|b1|2|a|1|3|b1|2|a|1|3|b
;
Now a simple DATA step can write the report.
filename report 'myreport.txt';
data _null_;
file report dsd dlm='|' ;
set have end=eof;
if _n_=1 then put
32*'#'
/ '###Game Of Thrones'
/ 32*'#'
/ 'Number of Candidates = ' ncandidates
// 32*'#'
/ 'Number of Games = ' ngames
// 32*'#'
/ 'Controlppt = ' controlppt
/ 'Controlgame = ' controlgame
/ 32*'#'
/ '# PPt 1 = ' ppt1
/ '# PPt 2 = ' ppt2
;
put var1-var21 ;
if eof then put 32*'#';
run;

Answer 2

This is a pretty customized report. what is your output destination, a text file, or PDF?
This can be achieved with PUT statements most likely, especially if to a text file. If it's HTML or RTF it may be slightly different.
Here's a rough approximation of what you need.
data _null_;
file '/folders/myfolders/demo.txt';
set sashelp.class;
put 'Name';
put '###########################';
put name;
put 'Sex';
put '###########################';
put (_numeric_) ('|');
put ;*empty line;
put ;*empty line;
run;

Answer 3

I tried this :
data have ;
ncandidates=1;
ngames=3; controlppt=1; controlgame=2;
ppt1='Abc';
ppt2='Bcd';
infile cards dsd dlm='|';
input (var1-var21) ($);
cards;
1|2|a|1|3|b1|2|a|1|3|b1|2|a|1|3|b1|2|a|1|3|b
1|2|a|1|3|b1|2|a|1|3|b1|2|a|1|3|b1|2|a|1|3|b
;
run;
data have1;
infile cards dsd dlm='|';
input (var1-var2) ($);
cards;
1|2
2|3
3|4
4|5
5|6
;
run;
filename report '/home/sas/l119834/myreport.txt';
data _null_;
file report dsd dlm='|' ;
eof=0;
do until(eof);
set have end=eof;
if _n_=1 then put
32*'#'
/ '###Game Of Thrones'
/ 32*'#'
/ 'Number of Candidates =' ncandidates
// 32*'#'
/ 'Number of Games = ' ngames
// 32*'#'
/ 'Controlppt = ' controlppt
/ 'Controlgame = ' controlgame
/ 32*'#'
/ '# PPt 1 = ' ppt1
/ '# PPt 2 = ' ppt2
/ 'Input.Data='
;
put var1-var21 ##;
if eof then put / 32*'#';
end;
put // 83*'#'
/ '### Output Data'
/ 83* '#'
/ '# Output field name, usage = Output Area|Name'
/ '# Area = 0, 1, 2, 3, 4, 5'
// 'output.Name='
;
eof1=0;
do until(eof1);
set have1 end=eof;
put var1-var2 ##;
end;
run;
and got this in the report:
################################
###Game Of Thrones
################################
Number of Candidates =1
################################
Number of Games = 3
################################
Controlppt = 1
Controlgame = 2
################################
# PPt 1 = Abc
# PPt 2 = Bcd
1|2|a|1|3|b1|2|a|1|3|b1|2|a|1|3|b1|2|a|1|3|b|################################
###Game Of Thrones
################################
Number of Candidates =1
################################
Number of Games = 3
################################
Controlppt = 1
Controlgame = 2
################################
Input.Data=
# PPt 1 = Abc
# PPt 2 = Bcd
1|2|a|1|3|b1|2|a|1|3|b1|2|a|1|3|b1|2|a|1|3|b
################################
###################################################################################
### Output Data
###################################################################################
# Output field name, usage = Output Area|Name
# Area = 0, 1, 2, 3, 4, 5
output.Name=
1|2|2|3|3|4|4|5|5|6
So, the first half is repeated twice in the output and Input.Name and the actual inputs vars are output on different lines,whereas I wanted it to be something like : input.Data=1|2|a|1|3|b1|2|a|1|3|b1|2|a|1|3|b1|2|a|1|3|b